setup.iss

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define OpenOCDName "OpenOCD"
#define OpenOCDVersion "0.10.0"
#define OpenOCDURL "http://openocd.org/"

#define MyAppName OpenOCDName + " " + OpenOCDVersion
#define MyAppVersion "1.0.1"
#define MyAppPublisher "Kouji Matsui (@kekyo2)"
#define MyAppURL "https://github.com/kekyo/OpenOCDonMinGW"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{85E6C5DE-A123-4E8E-81F8-DAC2BFE20F61}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}
VersionInfoVersion={#OpenOCDVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
AppCopyright={#OpenOCDURL}
DefaultDirName={pf}\{#OpenOCDName}
DefaultGroupName={#OpenOCDName}
LicenseFile=stage\openocd-{#OpenOCDVersion}\COPYING
InfoBeforeFile=stage\openocd-{#OpenOCDVersion}\README
OutputDir=artifacts
OutputBaseFilename=openocd-{#OpenOCDVersion}_i686-w64-mingw32_{#MyAppVersion}-setup
Compression=lzma
SolidCompression=yes
AllowUNCPath=false
PrivilegesRequired=admin

DisableWelcomePage=no
DisableDirPage=no

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: modifypath; Description: &Add application directory to your system path

[Files]
Source: "stage\i686-w64-mingw32\openocd-{#OpenOCDVersion}\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "stage\openocd-{#OpenOCDVersion}\ChangeLog"; DestDir: "{app}"; Flags: ignoreversion
Source: "stage\openocd-{#OpenOCDVersion}\COPYING"; DestDir: "{app}"; Flags: ignoreversion
Source: "stage\openocd-{#OpenOCDVersion}\README"; DestDir: "{app}"; Flags: ignoreversion

[Registry]
Root: HKLM; Subkey: "Software\{#OpenOCDName}"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\{#OpenOCDName}"; ValueType: string; ValueName: "Path"; ValueData: "{app}"
Root: HKLM; Subkey: "Software\{#OpenOCDName}"; ValueType: string; ValueName: "Version"; ValueData: "{#OpenOCDVersion}"
Root: HKLM; Subkey: "Software\{#OpenOCDName}"; ValueType: string; ValueName: "SetupVersion"; ValueData: "{#MyAppVersion}"

[Code]
const
	ModPathName = 'modifypath';
	ModPathType = 'system';

function ModPathDir(): TArrayOfString;
begin
	setArrayLength(Result, 1)
	Result[0] := ExpandConstant('{app}\bin');
end;

#include "modpath.iss"