build.gradle

/*
 * SPDX-License-Identifier: Apache-2.0
 *
 * Copyright 2015-2021 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
plugins {
    id 'org.kordamp.gradle.java-project'
}

if (!project.hasProperty('sonatypeUsername')) ext.sonatypeUsername = '**undefined**'
if (!project.hasProperty('sonatypePassword')) ext.sonatypePassword = '**undefined**'

config {
    release = (rootProject.findProperty('release') ?: false).toBoolean()

    info {
        name          = 'jsr377-api'
        vendor        = 'JSR-377'
        description   = 'JSR 377 - Desktop|Embedded Application API'
        inceptionYear = '2015'
        tags          = ['desktop', 'java', 'jsr377']

        links {
            website      = 'https://github.com/jsr377/jsr377-api'
            issueTracker = 'https://github.com/jsr377/jsr377-api/issues'
            scm          = 'https://github.com/jsr377/jsr377-api.git'
        }

        people {
            person {
                id    = 'aalmiray'
                name  = 'Andres Almiray'
                roles = ['Spec Lead', 'Developer']
            }
        }

        specification {
            title = 'JSR-377 API'
        }

        implementation { enabled = false }

        credentials {
            sonatype {
                username = project.sonatypeUsername
                password = project.sonatypePassword
            }
        }
    }

    licensing {
        licenses {
            license {
                id = 'Apache-2.0'
            }
        }
    }

    stats {
        formats = ['xml', 'txt']
    }

    docs {
        javadoc {
            autoLinks {
                enabled = false
            }
        }
    }
}

allprojects {
    apply plugin: 'idea'

    repositories {
        mavenCentral()
    }
}

idea {
    project {
        jdkName rootProject.sourceCompatibility
        languageLevel rootProject.sourceCompatibility
    }
}

subprojects { subproj ->
    plugins.withType(JavaPlugin) {
        subproj.tasks.withType(JavaCompile) {
            sourceCompatibility = rootProject.sourceCompatibility
            targetCompatibility = rootProject.sourceCompatibility
            options.compilerArgs = ['-Xlint:all', '-Xlint:deprecation', '-Xlint:unchecked']
        }
    }
}