build.gradle

buildscript {
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.5.1'
    }
}

repositories {
    google()
}

project.ext {
    //Common settings for most builds
    //Note that Android Studio does not know about the 'ext' module and will warn
    buildToolsVersion = '34.0.0' //Update Travis manually
    compileSdk = 34 //Update Travis manually
    targetSdk = 34
    minSdk = 21

    appcompat_version = "1.7.0"
    annotation_version = "1.6.0"
    preference_version = "1.2.1"
    //Note: Play Services later than 11.0.4 disables wear, requires a rewrite of NodeApi.NodeListener
    googlePlayServicesVersion = '21.3.0'
    googleWearVersion = '2.9.0'

    junitVersion = '4.13.2'
    mockitoVersion = '3.11.2'

    //The Git tag for the release must be identical for F-Droid
    versionName = '2.8.0.0'
    versionCode = 340
    latestBaseVersionCode = minSdk * 1000000

    // F-Droid builds only allow free software (wear dir deleted at builds)
    allowNonFree = !project.hasProperty('org.runnerup.free') && rootProject.file("wear").exists()
    // wear disabled, requires Play services migration
    enableWear = false

    // Note: AntPlus may have to be downloaded explicitly due to licensing
    // Therefore, the .aar file may not be redistributed in the RU repo
    antPlusLibPath = "$rootDir/ANT-Android-SDKs/ANT+_Android_SDK/API"
    antPlusLibName = "antpluginlib_3-9-0"
    if (!allowNonFree || project.hasProperty('org.runnerup.hr.disableAntPlus') || !rootProject.file(antPlusLibPath+'/'+antPlusLibName+'.aar').exists()) {
        antPlusLibName = ""
    }

    // ApplicationId (possibly with a .debug suffix) shared Android and Wear
    // Separate Id allows simultaneous installation
    if (!rootProject.ext.allowNonFree) {
        // Separate applicationId for the free version (must be first)
        applicationId = "org.runnerup.free"
    } else {
        applicationId = "org.runnerup"
    }
}

// Special setup for antPlusLib, not allowed to copy the .aar and create mavenLocal
// Raises warning:
// AGPBI: {"kind":"warning","text":"Using flatDir should be avoided because it doesn't support any meta-data formats.","sources":[{}]}
allprojects {
    repositories {
        if (rootProject.ext.antPlusLibName) {
            flatDir { dirs rootProject.ext.antPlusLibPath }
        }
    }
}