Disable flymake overlay click handler for code actions

[angrybacon]

I would like to be able to disable the click handler on code actions

I'm not sure how far you want to allow users to customize the properties applied to diagnostic types, so I wasn't able to come up with ready-to-review changes in a PR. Instead I tried a couple things locally until I was satisfied with the level of verbosity required in my configuration file in order to disable the click handler and mouse face, while still enabling other possible customization scenarios from other users eg. use right-click to trigger code action, apply a different face.

eglot.el: https://github.com/joaotavora/eglot/blob/a697084/eglot.el#L1713-L1721

(defcustom eglot-overlay-control-properties-overrides nil)

(defun eglot--overlay-control-properties (priority-offset)
  (let ((default `((keymap . ,(let ((map (make-sparse-keymap)))
                                (define-key map [mouse-1]
                                  (eglot--mouse-call 'eglot-code-actions))
                                map))
                   (mouse-face . highlight)
                   (priority . ,(+ 50 priority-offset))))
        (result (copy-alist eglot-overlay-control-properties-overrides)))
    ;; NOTE This doesn't maintain order and doesn't remove empty properties.
    ;;      Is there a more established way of merging 2 alists?
    (dolist (it default result)
      (unless (assoc (car it) result)
        (push it result)))))

 (cl-loop for i from 1
          for type in '(eglot-note eglot-warning eglot-error )
-         do (put type 'flymake-overlay-control
-                 `((mouse-face . highlight)
-                   (priority . ,(+ 50 i))
-                   (keymap . ,(let ((map (make-sparse-keymap)))
-                                (define-key map [mouse-1]
-                                  (eglot--mouse-call 'eglot-code-actions))
-                                map)))))
+         do (put type 'flymake-overlay-control (eglot--overlay-control-properties i)))

dotemacs.el

(setq eglot-overlay-control-properties-overrides '((keymap . nil)
                                                   (mouse-face . nil)))

I first considered a simple boolean defcustom to enable or disable the keymap and mouse-face specifically but I feel it wasn't customizable enough. I also wasn't able to determine whether it should warrant initializing eglot-ignored-server-capabilities with :codeActionProvider.

Btw, there is a small typo there:

-eglot-ignored-server-capabilites
+eglot-ignored-server-capabilities

[lhjok]

I have the same idea as you, but it seems that developers are not interested.

[lhjok]

Unable to set, we have to use lsp-mode

[joaotavora]

I think it's much easier to disable it like this.

(put 'eglot-node 'flymake-overlay-control nil)
(put 'eglot-warning 'flymake-overlay-control nil)
(put 'eglot-error 'flymake-overlay-control nil)

I'll accept a PR that decides which Flymake error classes to choose (eglot-kind with the current behaviour or regular vanilla) based on eglot-ignored-server-capabilities. Then turning this off should be easier.

@lhjok I'm sorry I didn't reply to your issue but I didn't have much time and I couldn't make head or tails of it. I hope the above can help you.

[russellmcc]

Thanks for the hint! There's a small typo (node instead of note) in your code block, should be

(put 'eglot-note 'flymake-overlay-control nil)
(put 'eglot-warning 'flymake-overlay-control nil)
(put 'eglot-error 'flymake-overlay-control nil)

Putting this in my 'eglot-managed-mode-hook is working great for me.