[LR1121] is there Hi Band Ping-Pong example?

[klabshowroom]

I use the Ping-Pong example, and set frequency to Hi Band, it fail to run.

Is there any workable example for Hi Band?

Thanks for help.

[jgromes]

"it fail to run" can mean many things. Is there an error code? A crash? Did you board spontaneously combust?

It should be enough to call setFrequency with the appropriate value and then setOutputPower to select the high-frequency PA (as the documentation of LR1121::setFrequency says). Did you follow that? And can you show us the code in which you attempted it?

Opening discussions and issues with elementary information missing is not a good form. We don't have your hardware, so we can only debug the problem using the information you give us. Fixing issues with plenty of information given is a joy; having to piece together what is happening from partial descriptions given randomly is a nightmare...

[klabshowroom]

@jgromes sorry for my description, and will describe in detail.
my H/W is the EVB from Semtech:

I use the ping-pong example, when use the frequency is 920.3MHz, it work well, my code is :
/*
RadioLib LR11x0 Ping-Pong Example

For default module settings, see the wiki page
https://github.com/jgromes/RadioLib/wiki/Default-configuration#lr11x0---lora-modem

For full API reference, see the GitHub Pages
https://jgromes.github.io/RadioLib/
*/

// include the library
#include <RadioLib.h>

// uncomment the following only on one
// of the nodes to initiate the pings
#define INITIATING_NODE

// LR1110 has the following connections:
// NSS pin: 10
// IRQ pin: 2
// NRST pin: 3
// BUSY pin: 9
#define PIN_SPI_SS 7 //D7
#define PIN_SPI_MOSI 11 //D11
#define PIN_SPI_MISO 12 //D12
#define PIN_SPI_SCK 13 //D13

LR1121 radio = new Module(PIN_SPI_SS, 5, A0, 3);

// set RF switch configuration for Wio WM1110
// Wio WM1110 uses DIO5 and DIO6 for RF switching
// NOTE: other boards may be different!
//static const uint32_t rfswitch_dio_pins[] = {
// RADIOLIB_LR11X0_DIO5, RADIOLIB_LR11X0_DIO6,
// RADIOLIB_NC, RADIOLIB_NC, RADIOLIB_NC
//};
static const uint32_t rfswitch_dio_pins[] = {
5, 6,
RADIOLIB_NC, RADIOLIB_NC, RADIOLIB_NC
};

static const Module::RfSwitchMode_t rfswitch_table[] = {
// mode DIO5(V1) DIO6(V2)
{ LR11x0::MODE_STBY, { LOW, LOW } }, //shutdown
{ LR11x0::MODE_RX, { HIGH, LOW } }, //J3
{ LR11x0::MODE_TX, { HIGH, HIGH } }, //J2, RFO_LP_LF
{ LR11x0::MODE_TX_HP, { LOW, HIGH } }, //J1, RFO_HP_LF
{ LR11x0::MODE_TX_HF, { LOW, LOW } },
{ LR11x0::MODE_GNSS, { LOW, LOW } },
{ LR11x0::MODE_WIFI, { LOW, LOW } },
END_OF_MODE_TABLE,
};

// save transmission states between loops
int transmissionState = RADIOLIB_ERR_NONE;

// flag to indicate transmission or reception state
bool transmitFlag = false;

// flag to indicate that a packet was sent or received
volatile bool operationDone = false;

// this function is called when a complete packet
// is transmitted or received by the module
// IMPORTANT: this function MUST be 'void' type
// and MUST NOT have any arguments!
#if defined(ESP8266) || defined(ESP32)
ICACHE_RAM_ATTR
#endif
void setFlag(void) {
// we sent or received a packet, set the flag
operationDone = true;
}

void setup() {
Serial.begin(115200);

// set RF switch control configuration
// this has to be done prior to calling begin()
radio.setRfSwitchTable(rfswitch_dio_pins, rfswitch_table);

// initialize LR1121 with default settings
Serial.print(F("[LR1121] Initializing ... "));
int state = radio.begin(920.3, 125.0, 10, 5, RADIOLIB_LR11X0_LORA_SYNC_WORD_PRIVATE, 10, 8, 0);
//LR1110::begin(434.0, 125.0, 9, 7, RADIOLIB_LR11X0_LORA_SYNC_WORD_PRIVATE, 10, 8, 1.6);
//LR1110::begin(freq, BW, SF, 4/7, RADIOLIB_LR11X0_LORA_SYNC_WORD_PRIVATE, power, preamble length, tcxo voltage);
if (state == RADIOLIB_ERR_NONE) {
Serial.println(F("success!"));
} else {
Serial.print(F("failed, code "));
Serial.println(state);
while (true) { delay(10); }
}

// set the function that will be called
// when new packet is received
radio.setIrqAction(setFlag);
//Serial.print("Tx Power = "); Serial.println(CurrentTxPower);
//radio.setOutputPower(2); // Set power to 14 dBm

#if defined(INITIATING_NODE)
// send the first packet on this node
Serial.print(F("[LR1121] Sending first packet ... "));
transmissionState = radio.startTransmit("Hello World!");
transmitFlag = true;
#else
// start listening for LoRa packets on this node
Serial.print(F("[LR1110] Starting to listen ... "));
state = radio.startReceive();
if (state == RADIOLIB_ERR_NONE) {
Serial.println(F("success!"));
} else {
Serial.print(F("failed, code "));
Serial.println(state);
while (true) { delay(10); }
}
#endif
}

void loop() {
// check if the previous operation finished
if(operationDone) {
// reset flag
operationDone = false;

if(transmitFlag) {
  // the previous operation was transmission, listen for response
  // print the result
  if (transmissionState == RADIOLIB_ERR_NONE) {
    // packet was successfully sent
    Serial.println(F("transmission finished!"));

  } else {
    Serial.print(F("failed, code "));
    Serial.println(transmissionState);

  }

  // listen for response
  radio.startReceive();
  transmitFlag = false;

} else {
  // the previous operation was reception
  // print data and send another packet
  String str;
  int state = radio.readData(str);

  if (state == RADIOLIB_ERR_NONE) {
    // packet was successfully received
    Serial.println(F("[LR1110] Received packet!"));

    // print data of the packet
    Serial.print(F("[LR1110] Data:\t\t"));
    Serial.println(str);

    // print RSSI (Received Signal Strength Indicator)
    Serial.print(F("[LR1110] RSSI:\t\t"));
    Serial.print(radio.getRSSI());
    Serial.println(F(" dBm"));

    // print SNR (Signal-to-Noise Ratio)
    Serial.print(F("[LR1110] SNR:\t\t"));
    Serial.print(radio.getSNR());
    Serial.println(F(" dB"));

  }

  // wait a second before transmitting again
  delay(1000);

  // send another one
  Serial.print(F("[LR1110] Sending another packet ... "));
  transmissionState = radio.startTransmit("Hello World!");
  transmitFlag = true;
}

}
}

the serial monitor show:
[LR1121] Initializing ... RLB_DBG:
RadioLib Info
Version: "7.0.2.0"
Platform: "Arduino STM32 (official)"
Compiled: "Dec 27 2024" "09:04:32"
RLB_DBG: Found LR11x0: RADIOLIB_LR11X0_CMD_GET_VERSION = 0x03
RLB_DBG: Base FW version: 1.3
RLB_DBG: M LR11x0
success!
[LR1121] Sending first packet ... transmission finished!

if I modify the requency to be 2400.0MHz:
int state = radio.begin(2400.0, 125.0, 10, 5, RADIOLIB_LR11X0_LORA_SYNC_WORD_PRIVATE, 10, 8, 0);

the serial monitor will show fail:
[LR1121] Initializing ... RLB_DBG:
RadioLib Info
Version: "7.0.2.0"
Platform: "Arduino STM32 (official)"
Compiled: "Dec 27 2024" "09:49:16"
RLB_DBG: Found LR11x0: RADIOLIB_LR11X0_CMD_GET_VERSION = 0x03
RLB_DBG: Base FW version: 1.3
RLB_DBG: M LR11x0
failed, code -8

[jgromes]

See, now it's easy: you got an error code, so you have to find out what it means. Either in the API reference, or in our online decoder. You will find that -8 is RADIOLIB_ERR_INVALID_BANDWIDTH. But why is that? Checking the API reference for LR11x0::setBandwidth here, you will find that for the 2.4 GHz band, the LoRa bandwidth values are different than in the sub-GHz band. It's all in the documentation ;)

[klabshowroom]

Hi Jgromes,
Thanks for your help, after setting the BW to be 203.125KHz, and it work well now.