add pipeline aggregator plugin support

docs/Home.md

@@ -32,6 +32,8 @@ scripts, including [[tests for DSL scripts|Testing DSL Scripts]] and [[IDE Suppo
 Browse the Jenkins issue tracker to see any [open issues](https://issues.jenkins-ci.org/issues/?filter=15140).
 
 ## Release Notes
+* 1.79 (unreleased)
+  * Added support for the [Pipeline Aggregator Plugin](https://plugins.jenkins.io/pipeline-aggregator-view)
 * 1.78.1 (October 27 2021)
   * Fix: Ensure API Viewer is packaged correctly into the built plugin ([JENKINS-66988](https://issues.jenkins.io/browse/JENKINS-66988))
 * 1.78 (October 27 2021)

job-dsl-core/src/main/docs/examples/javaposse/jobdsl/dsl/DslFactory/pipelineAggregatorView.groovy

@@ -0,0 +1,5 @@
+pipelineAggregatorView('pipeline-aggregator-view') {
+    filterRegex('.*Pipeline')
+    onlyLastBuild()
+    useCondensedTables()
+}

job-dsl-core/src/main/docs/examples/javaposse/jobdsl/dsl/views/PipelineAggregatorView/buildHistorySize.groovy

@@ -0,0 +1,3 @@
+pipelineAggregatorView('pipeline-aggregator-view') {
+    buildHistorySize(10)
+}

job-dsl-core/src/main/docs/examples/javaposse/jobdsl/dsl/views/PipelineAggregatorView/description.groovy

@@ -0,0 +1,3 @@
+pipelineAggregatorView('pipeline-aggregator-view') {
+    description('View description')
+}

job-dsl-core/src/main/docs/examples/javaposse/jobdsl/dsl/views/PipelineAggregatorView/filterRegex.groovy

@@ -0,0 +1,3 @@
+pipelineAggregatorView('pipeline-aggregator-view') {
+    filterRegex('.*Pipeline')
+}

job-dsl-core/src/main/docs/examples/javaposse/jobdsl/dsl/views/PipelineAggregatorView/fontSize.groovy

@@ -0,0 +1,3 @@
+pipelineAggregatorView('pipeline-aggregator-view') {
+    fontSize(10)
+}

job-dsl-core/src/main/docs/examples/javaposse/jobdsl/dsl/views/PipelineAggregatorView/onlyLastBuild.groovy

@@ -0,0 +1,3 @@
+pipelineAggregatorView('pipeline-aggregator-view') {
+    onlyLastBuild()
+}

job-dsl-core/src/main/docs/examples/javaposse/jobdsl/dsl/views/PipelineAggregatorView/useCondensedTables.groovy

@@ -0,0 +1,3 @@
+pipelineAggregatorView('pipeline-aggregator-view') {
+    useCondensedTables()
+}

job-dsl-core/src/main/docs/examples/javaposse/jobdsl/dsl/views/PipelineAggregatorView/useScrollingCommits.groovy

@@ -0,0 +1,3 @@
+pipelineAggregatorView('pipeline-aggregator-view') {
+    useScrollingCommits()
+}

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/JobParent.groovy

@@ -17,6 +17,7 @@ import javaposse.jobdsl.dsl.views.DashboardView
 import javaposse.jobdsl.dsl.views.DeliveryPipelineView
 import javaposse.jobdsl.dsl.views.ListView
 import javaposse.jobdsl.dsl.views.NestedView
+import javaposse.jobdsl.dsl.views.PipelineAggregatorView
 import javaposse.jobdsl.dsl.views.SectionedView
 
 import static javaposse.jobdsl.dsl.Preconditions.checkNotNull
@@ -174,6 +175,16 @@ abstract class JobParent extends Script implements DslFactory {
         processItem(name, Folder, closure)
     }
 
+    /**
+     * @since 1.78
+     */
+    @Override
+    PipelineAggregatorView pipelineAggregatorView(
+            String name, @DslContext(PipelineAggregatorView) Closure closure = null
+    ) {
+        processView(name, PipelineAggregatorView, closure)
+    }
+
     @Override
     void configFiles(@DslContext(ConfigFilesContext) Closure closure) {
     }

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/ViewFactory.groovy

@@ -7,6 +7,7 @@ import javaposse.jobdsl.dsl.views.DashboardView
 import javaposse.jobdsl.dsl.views.DeliveryPipelineView
 import javaposse.jobdsl.dsl.views.ListView
 import javaposse.jobdsl.dsl.views.NestedView
+import javaposse.jobdsl.dsl.views.PipelineAggregatorView
 import javaposse.jobdsl.dsl.views.SectionedView
 
 /**
@@ -129,4 +130,21 @@ interface ViewFactory extends Context {
      */
     @RequiresPlugin(id = 'dashboard-view', minimumVersion = '2.9.7', failIfMissing = true)
     DashboardView dashboardView(String name, @DslContext(DashboardView) Closure closure)
+
+    /**
+     * Creates or updates a view showing the history of pipelines with stage information.
+     *
+     * @see #pipelineAggregatorView(java.lang.String, groovy.lang.Closure)
+     * @since 1.78
+     */
+    @RequiresPlugin(id = 'pipeline-aggregator-view', minimumVersion = '1.8', failIfMissing = true)
+    PipelineAggregatorView pipelineAggregatorView(String name)
+
+    /**
+     * Creates or updates a view showing the history of pipelines with stage information.
+     *
+     * @since 1.78
+     */
+    @RequiresPlugin(id = 'pipeline-aggregator-view', minimumVersion = '1.8', failIfMissing = true)
+    PipelineAggregatorView pipelineAggregatorView(String name, @DslContext(PipelineAggregatorView) Closure closure)
 }

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/views/NestedViewsContext.groovy

@@ -80,6 +80,16 @@ class NestedViewsContext extends AbstractExtensibleContext implements ViewFactor
         processView(name, DashboardView, closure)
     }
 
+    /**
+     * @since 1.78
+     */
+    @Override
+    PipelineAggregatorView pipelineAggregatorView(
+            String name, @DslContext(PipelineAggregatorView) Closure closure = null
+    ) {
+        processView(name, PipelineAggregatorView, closure)
+    }
+
     @Override
     protected void addExtensionNode(Node node) {
         views << new View(jobManagement, node['name'].text()) {

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/views/PipelineAggregatorView.groovy

@@ -0,0 +1,87 @@
+package javaposse.jobdsl.dsl.views
+
+import javaposse.jobdsl.dsl.JobManagement
+import javaposse.jobdsl.dsl.NoDoc
+import javaposse.jobdsl.dsl.View
+
+import static javaposse.jobdsl.dsl.Preconditions.checkArgument
+import static javaposse.jobdsl.dsl.Preconditions.checkNotNullOrEmpty
+
+class PipelineAggregatorView extends View {
+
+    PipelineAggregatorView(JobManagement jobManagement, String name) {
+        super(jobManagement, name)
+    }
+
+    /**
+     * Set the number of most recent builds to display. Defaults to {@code 16}.
+     */
+    void buildHistorySize(int buildHistorySize) {
+        checkArgument(buildHistorySize > 0, 'buildHistorySize must be positive integer')
+
+        configure {
+            it / methodMissing('buildHistorySize', buildHistorySize)
+        }
+    }
+
+    /**
+     * Set regular expression used for filtering pipelines to be displayed.
+     */
+    void filterRegex(String filterRegex) {
+        checkNotNullOrEmpty(filterRegex, 'filterRegex must be specified')
+
+        configure {
+            it / methodMissing('filterRegex', filterRegex)
+        }
+    }
+
+    /**
+     * Set font size. Defaults to {@code 16}.
+     */
+    void fontSize(int fontSize) {
+        checkArgument(fontSize > 0, 'fontSize must be positive integer')
+
+        configure {
+            it / methodMissing('fontSize', fontSize)
+        }
+    }
+
+    /**
+     * Display only last pipeline build. Defaults to {@code false}.
+     */
+    void onlyLastBuild(boolean onlyLastBuild = true) {
+        configure {
+            it / methodMissing('onlyLastBuild', onlyLastBuild)
+        }
+    }
+
+    /**
+     * Use condensed tables. Defaults to {@code false}.
+     */
+    void useCondensedTables(boolean useCondensedTables = true) {
+        configure {
+            it / methodMissing('useCondensedTables', useCondensedTables)
+        }
+    }
+
+    /**
+     * Use scrolling commits. Defaults to {@code false}.
+     */
+    void useScrollingCommits(boolean useScrollingCommits = true) {
+        configure {
+            it / methodMissing('useScrollingCommits', useScrollingCommits)
+        }
+    }
+
+    @Override
+    @NoDoc
+    void filterBuildQueue(boolean filterBuildQueue = true) {
+        super.filterBuildQueue(filterBuildQueue)
+    }
+
+    @Override
+    @NoDoc
+    void filterExecutors(boolean filterExecutors = true) {
+        super.filterExecutors(filterExecutors)
+    }
+}

job-dsl-core/src/main/resources/javaposse/jobdsl/dsl/views/PipelineAggregatorView-template.xml

@@ -0,0 +1,11 @@
+<?xml version="1.1" encoding="UTF-8"?>
+<com.ooyala.jenkins.plugins.pipelineaggregatorview.PipelineAggregator>
+    <filterExecutors>false</filterExecutors>
+    <filterQueue>false</filterQueue>
+    <properties class="hudson.model.View$PropertyList"/>
+    <fontSize>16</fontSize>
+    <buildHistorySize>16</buildHistorySize>
+    <useCondensedTables>false</useCondensedTables>
+    <onlyLastBuild>false</onlyLastBuild>
+    <useScrollingCommits>false</useScrollingCommits>
+</com.ooyala.jenkins.plugins.pipelineaggregatorview.PipelineAggregator>

job-dsl-core/src/test/groovy/javaposse/jobdsl/dsl/JobParentSpec.groovy

@@ -15,6 +15,7 @@ import javaposse.jobdsl.dsl.views.DashboardView
 import javaposse.jobdsl.dsl.views.DeliveryPipelineView
 import javaposse.jobdsl.dsl.views.ListView
 import javaposse.jobdsl.dsl.views.NestedView
+import javaposse.jobdsl.dsl.views.PipelineAggregatorView
 import javaposse.jobdsl.dsl.views.SectionedView
 import spock.lang.Specification
 
@@ -247,6 +248,31 @@ class JobParentSpec extends Specification {
         1 * jobManagement.requireMinimumPluginVersion('cloudbees-folder', '5.14', true)
     }
 
+    def 'pipeline aggregator view'() {
+        when:
+        View view = parent.pipelineAggregatorView('test') {
+            description('foo')
+        }
+
+        then:
+        view.name == 'test'
+        view instanceof PipelineAggregatorView
+        parent.referencedViews.contains(view)
+        view.node.description[0].text() == 'foo'
+        1 * jobManagement.requireMinimumPluginVersion('pipeline-aggregator-view', '1.8', true)
+    }
+
+    def 'pipeline aggregator view without closure'() {
+        when:
+        View view = parent.pipelineAggregatorView('test')
+
+        then:
+        view.name == 'test'
+        view instanceof PipelineAggregatorView
+        parent.referencedViews.contains(view)
+        1 * jobManagement.requireMinimumPluginVersion('pipeline-aggregator-view', '1.8', true)
+    }
+
     def 'readFileInWorkspace from seed job'() {
         jobManagement.readFileInWorkspace('foo.txt') >> 'hello'