How to use terraform's github_repository for already existing repositories?

[aminbaa]

I use Terraform for creating non-existing repositories as below:

# main.tf
provider "github" {
    token = var.gh_token
    base_url = "#######My Company Base URL####"
    owner = "#####organization-name#####"
}


# repositories.tf
resource "github_repository" "terraform-created-repo" {
  name = "terraform-created-repo"
  description = "This is a description"
  visibility = "internal"
  auto_init = true
  has_issues = true
}


# variables.tf
variable "gh_token" {
  description = "Token for GitHub"
  type = string
}


# versions.tf
terraform {
  required_providers {
    github = {
      source  = "integrations/github"
      version = "~> 5.0"
    }
  }
}

Then run these commands

export TF_VAR_gh_token=....
terraform init
terraform plan
terraform apply

it creates the repository for me.

---

However, if I manually create a repository and want to add a description and other metadata as explained here it does not work because it complains

422 Validation Failed [{Resource:Repository Field:name Code:custom Message:name already exists on this account}]

How can I add such metadata data to a repository?

Note that I don't want to recreate the repository because I don't want the content of the repo to be lost. I just want to add the information to an already existing repository

[stefanfreitag]

Hi @aminbaa, did you try to import the repository?
Similar to

$ terraform import github_repository.terraform terraform

[laughedelic]

Note that with Terraform 1.5+ you can do that within the code using import block:

import {
  to = github_repository.existing_repo_name
  id = ... # that repository ID
}

You can either add that resource manually in the code:

resource "github_repository" "existing_repo_name" {
  name = "existing-repo-name"
  # you will have to pre-fill all required fields 
}

This might be inconvenient because you have to manually fill in the fields of the resource. A better (but experimental) option is to generate the code for that resource by running

terraform plan -generate-config-out=existing-repos.tf

Then edit the generated code. In the plan you will see that resources are imported, not re-created. And once you apply, you can either keep or remove the import blocks (they are idempotent).