build.gradle

buildscript {
    ext.kotlin_version = '1.7.21'
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.4.0'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:1.7.21"
        // Maven Central Publish
        classpath "com.vanniktech:gradle-maven-publish-plugin:0.24.0"
        // Dokka
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:1.7.10"
    }
}

apply plugin: 'org.jetbrains.dokka'

afterEvaluate {
    if (tasks.findByName('dokkaGfmPartial') == null) {
        // If dokka isn't enabled on this module, skip
        return
    }
    tasks.named('dokkaGfmPartial') {
        dokkaSourceSets.configureEach {
            reportUndocumented.set(true)
            skipEmptyPackages.set(true)
            skipDeprecated.set(true)
            jdkVersion.set(8)

            // Add Android SDK packages
            noAndroidSdkLink.set(false)

            // AndroidX + Compose docs
            externalDocumentationLink {
                url.set(new URL("https://developer.android.com/reference/"))
                packageListUrl.set(new URL("https://developer.android.com/reference/androidx/package-list"))
            }
            externalDocumentationLink {
                url.set(new URL("https://developer.android.com/reference/kotlin/"))
                packageListUrl.set(new URL("https://developer.android.com/reference/kotlin/androidx/package-list"))
            }

            sourceLink {
                localDirectory.set(project.file("src/main/kotlin"))
                // URL showing where the source code can be accessed through the web browser
                remoteUrl.set(new URL("https://github.com/sceneview/sceneview-android/blob/main/${project.name}/src/main/kotlin"))
                // Suffix which is used to append the line number to the URL. Use #L for GitHub
                remoteLineSuffix.set("#L")
            }
        }
    }
}

allprojects {
    plugins.withId("com.vanniktech.maven.publish") {
        /*
        mavenPublish {
            sonatypeHost = "S01"
        }
         */
        publishing {
            repositories {
                maven {
                    name = "GithubPackages"
                    url = "https://maven.pkg.github.com/homingos/sceneview-android"
                    // username and password (a personal Github access token) should be specified as
                    // `githubPackagesUsername` and `githubPackagesPassword` Gradle properties or alternatively
                    // as `ORG_GRADLE_PROJECT_githubPackagesUsername` and `ORG_GRADLE_PROJECT_githubPackagesPassword`
                    // environment variables
                    credentials(PasswordCredentials)
                }
            }
        }
    }
}