Unhelpful/unclear error message when required provider configurations are missing

[stusklinar]

Terraform Version

1.7.1

Terraform Configuration Files

main.tf

terraform {
  required_version = "<= 1.7.1"
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = ">= 3.24.0, < 4.0.0"
      configuration_aliases = [
        azurerm.azsubscription
      ]
    }
  }

variable "name" {
  description = "Name of the Resource Group"
  type        = string
}

variable "location" {
  description = "Location of the Resource Group"
  type        = string
  default     = "UK South"
}
resource "azurerm_resource_group" "this" {
  name     = var.name
  location = var.location
}

test.tftest.hcl

provider "azurerm" {
  features {}
}

run "validate_functions" {

  command = apply

    providers = {
    azurerm.azsubscription = azurerm
  }

  variables {
    name     = "rg-terraform-testing"
    location = "uksouth"
  }

  assert {
    condition     = azurerm_resource_group.this.name == var.name
    error_message = "function name did not match expected"
  }

  assert {
    condition     =  azurerm_resource_group.this.location == var.location
    error_message = "location did not match uksouth"
  }

}

Debug Output

TF Trace Log Output

Expected Behavior

Tests should pass

Actual Behavior

tests/module.tftest.hcl... in progress
  run "setup_tests"... pass
  run "validate_functions"... fail
╷
│ Error: Insufficient features blocks
│ 
│   on <empty> line 0:
│   (source code not available)
│ 
│ At least 1 "features" blocks are required.
╵
tests/module.tftest.hcl... tearing down
tests/module.tftest.hcl... fail

Failure! 1 passed, 1 failed.

Steps to Reproduce

terraform init
terraform test

Additional Context

This is a largely reduced version of our problem - but illustrates the issue much the same.

We have modules that accept different providers for different subscriptions/accounts - in this simple mock-up we get the same error, of injecting a provider expects features.

References

• mock_provider does not work with providers that have required configuration blocks (e.g. azurerm) #34489

[liamcervante]

Hi @stusklinar, thanks for filing this!

The problem is that you are only providing a definition for the azurerm.azsubscription provider within the test and not the non-aliased azurerm provider which also requires a dedicated provider block with the features block set.

I think you can get your test to work if you expand the providers block within the run "validate_functions" like this:

providers = {
  azurerm = azurerm
  azurerm.azsubscription = azurerm
}

This provides a concrete provider definition for all the required providers in your configuration.

I do think that the error message you are receiving is super unhelpful, I'll expand on that in a follow up comment to keep things separate.

Hopefully this unblocks you!

[liamcervante]

On the error message, this isn't actually something that is being reported by the testing framework itself. If I add the provider block directly to your configuration and execute terraform plan I receive the same error:

terraform {
  required_version = "<= 1.7.1"
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = ">= 3.24.0, < 4.0.0"
      configuration_aliases = [
        azurerm.azsubscription
      ]
    }
  }
}

provider "azurerm" {
    alias = "azsubscription"

    features {}
}

variable "name" {
  description = "Name of the Resource Group"
  type        = string
}

variable "location" {
  description = "Location of the Resource Group"
  type        = string
  default     = "UK South"
}
resource "azurerm_resource_group" "this" {
  name     = var.name
  location = var.location
}

~/terraform/34594 > terraform plan 
var.name
  Name of the Resource Group

  Enter a value: thing


Planning failed. Terraform encountered an error while generating this plan.

╷
│ Error: Insufficient features blocks
│ 
│   on <empty> line 0:
│   (source code not available)
│ 
│ At least 1 "features" blocks are required.
╵

The (source code not available) message is because the provider block is not present in the config, so Terraform is creating a virtual configuration block which is missing the required block, and then reports the error without any source code available.

I'm going to change the title of this issue, and we can use it to track improving the error message for this case so that in future it will state the real problem, which is that the provider block must be explicitly provided in the configuration if we have required attributes or blocks.

Thanks!

[liamcervante]

We do actually add some additional context for missing provider config if the provider validation call itself fails. This happens here.

We don't any extra context if the schema validation itself fails (where the features block is marked as required) here.

I think we can just take the additional context we add in the first case, and also add it in the second case. Then we'd get an error that looks like this:

╷
│ Error: Invalid provider configuration
│ 
│ Provider "registry.terraform.io/hashicorp/azurerm" requires explicit configuration. Add a provider block to the root module and configure the
│ provider's required arguments as described in the provider documentation.
│ 
╵

Which provides a much better hint about the root cause of the problem, compared to the existing cryptic errors that are returned currently.

[stusklinar]

This is great - thanks for this - consider me unblocked

[github-actions]

I'm going to lock this issue because it has been closed for 30 days ⏳. This helps our maintainers find and focus on the active issues.
If you have found a problem that seems similar to this, please open a new issue and complete the issue template so we can capture all the details necessary to investigate further.