build.gradle

import org.gradle.internal.jvm.Jvm

buildscript {
    ext.kotlin_version = '2.1.0'
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.7.3'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath 'com.github.dcendents:android-maven-gradle-plugin:2.1'
    }
}

println "Gradle uses Java ${Jvm.current()}"

allprojects {
    repositories {
        google()
        mavenCentral()
        maven { url 'https://jitpack.io' }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

@SuppressWarnings('unused')
static def getTag() {
    // with local un-commited changes a -DIRTY is added
    def processChanges = "git diff-index --name-only HEAD --".execute()
    def dirty = ""
    if (!processChanges.text.toString().trim().isEmpty())
        dirty = "-DIRTY"

    def process = "git describe --tags".execute()
    return process.text.toString().trim() + dirty
}

@SuppressWarnings('unused')
static def getGitCommitCount() {
    def process = "git rev-list HEAD --count".execute()
    return process.text.toInteger()
}