Latte.cf

-- programs ------------------------------------------------

entrypoints Program ;

Program.   Program ::= [TopDef] ;

FnTopDef.  TopDef ::= FnDef ;

ClsDef.    TopDef ::= "class" Ident "{" [Field] [FnDef] "}" ;

ClsExtDef. TopDef ::= "class" Ident "extends" Ident "{" [Field] [FnDef] "}" ;

separator  nonempty TopDef "" ;

-- class members -------------------------------------------

FnDef.     FnDef ::= Type Ident "(" [Arg] ")" Block ;

separator  nonempty FnDef "" ;

Arg. 	   Arg ::= Type Ident ;

separator  Arg "," ;

Field.     Field ::= Type Ident ;

terminator Field ";" ;

-- statements ----------------------------------------------

Block.     Block ::= "{" [Stmt] "}" ;

separator  Stmt "" ;

Empty.     Stmt ::= ";" ;

BStmt.     Stmt ::= Block ;

Decl.      Stmt ::= Type [Item] ";" ;

NoInit.    Item ::= Ident ; 

Init.      Item ::= Ident "=" Expr ;

separator nonempty Item "," ;

Ass.       Stmt ::= Expr "=" Expr  ";" ;

Incr.      Stmt ::= Expr "++"  ";" ;

Decr.      Stmt ::= Expr "--"  ";" ;

Ret.       Stmt ::= "return" Expr ";" ;

VRet.      Stmt ::= "return" ";" ;

Cond.      Stmt ::= "if" "(" Expr ")" Stmt  ;

CondElse.  Stmt ::= "if" "(" Expr ")" Stmt "else" Stmt  ;

While.     Stmt ::= "while" "(" Expr ")" Stmt ;

SExp.      Stmt ::= Expr  ";" ;

-- Types ---------------------------------------------------

Int.       Type ::= "int" ;

Str.       Type ::= "string" ;

Bool.      Type ::= "boolean" ;

Void.      Type ::= "void" ;

ClsType.   Type ::= Ident ;

internal   Fun. Type ::= Type "(" [Type] ")" ;

internal   Char. Type ::= "Char" ;

internal   Ptr. Type ::= Type "*" ;

internal   Arr. Type ::= Type "[" Integer "]" ;

internal   VtableType. Type ::= Ident ;

separator  Type "," ;

-- Expressions ---------------------------------------------

ELitInt.   Expr6 ::= Integer ;

ELitTrue.  Expr6 ::= "true" ;

ELitFalse. Expr6 ::= "false" ;

EApp.      Expr6 ::= Ident "(" [Expr] ")" ;

EString.   Expr6 ::= String ;

ENew.      Expr6 ::= "new" Ident ;

ENull.     Expr6 ::= "(" Ident ")" "null" ;

EMApp.     Expr6 ::= Ident "." Ident "(" [Expr] ")" ;

EAcc.      Expr6 ::= Ident "." Ident ;

EVar.      Expr6 ::= Ident ;

Neg.       Expr5 ::= "-" Expr6 ;

Not.       Expr5 ::= "!" Expr6 ;

EMul.      Expr4 ::= Expr4 MulOp Expr5 ;

EAdd.      Expr3 ::= Expr3 AddOp Expr4 ;

ERel.      Expr2 ::= Expr2 RelOp Expr3 ;

EAnd.      Expr1 ::= Expr2 "&&" Expr1 ;

EOr.       Expr ::= Expr1 "||" Expr ;

coercions  Expr 6 ;

separator  Expr "," ;

-- operators -----------------------------------------------

Plus.      AddOp ::= "+" ;

Minus.     AddOp ::= "-" ;

Times.     MulOp ::= "*" ;

Div.       MulOp ::= "/" ;

Mod.       MulOp ::= "%" ;

LTH.       RelOp ::= "<" ;

LE.        RelOp ::= "<=" ;

GTH.       RelOp ::= ">" ;

GE.        RelOp ::= ">=" ;

EQU.       RelOp ::= "==" ;

NE.        RelOp ::= "!=" ;

-- comments ------------------------------------------------

comment    "#" ;

comment    "//" ;

comment    "/*" "*/" ;