BUILD.bazel

load("@bazel_tools//tools/build_defs/pkg:pkg.bzl", "pkg_tar")
#load("@build_bazel_rules_typescript//:defs.bzl", "ts_library", "ts_web_test")
load("@npm//@bazel/typescript:index.bzl", "ts_library")
load("@npm//@bazel/rollup:index.bzl", "rollup_bundle")
load("@npm//@bazel/karma:index.bzl", "karma_web_test", "karma_web_test_suite")
load("@npm//@bazel/jasmine:index.bzl", "jasmine_node_test")
load(":execute.bzl", "concat")

package(default_visibility = ["//:__subpackages__"])


# Building the distribution.

# Install the extension to ~/.local/share/gnome-shell/extensions
sh_binary(
    name = "install-extension",
    srcs = ["install-extension.sh"],
    data = [":dist.tar.gz"],
)

sh_binary(
    name = "concat",
    srcs = ["concat.sh"],
)

# Output a dist.tar.gz folder to bazel-bin for distribution.
pkg_tar(
    name = "dist",
    srcs = [":dist_files"],
    extension = "tar.gz",
    mode = "0664",
    strip_prefix = ".",
)

filegroup(
    name = "dist_files",
    srcs = [
        "extension.js",
        "hotkeys.js",
        "metadata.json",
        "prefs.js",
        "schemas/gschemas.compiled",
        "schemas/org.gnome.shell.extensions.gtile.gschema.xml",
        "settings.js",
    ],
)

exports_files([
    "tsconfig.json",
    "tsconfig-app.json",
])

# NOTE: this will move to node_modules/BUILD in a later release
filegroup(
    name = "node_modules",
    srcs = glob([
        "node_modules/**/*.js",
        "node_modules/**/*.d.ts",
        "node_modules/**/*.json",
    ]),
)

ts_library(
    name = "app_lib",
    srcs = ["app.ts"],
    tsconfig = "//:tsconfig-app.json",
    deps = [
        ":resize_lib",
        ":tilespec_lib",
    ],
)

ts_library(
    name = "entry_lib",
    srcs = ["entry.ts"],
    tsconfig = "//:tsconfig-app.json",
    deps = [":app_lib"],
)

ts_library(
    name = "tilespec_lib",
    srcs = ["tilespec.ts"],
    tsconfig = "//:tsconfig.json",
)

ts_library(
    name = "resize_lib",
    srcs = ["resize.ts"],
    tsconfig = "//:tsconfig.json",
    deps = [":tilespec_lib"],
)

ts_library(
    name = "tests",
    testonly = 1,
    srcs = [
        "resize.spec.ts",
        "tilespec.spec.ts",
    ],
    deps = [
        ":resize_lib",
        ":tilespec_lib",
        "@npm//@types/chai",
        "@npm//@types/mocha",
        "@npm//@types/jasmine",
        "@npm//chai",
        "@npm//jasmine",
        "@npm//mocha",
    ],
)

jasmine_node_test(
    name = "testing",
    deps = [
        ":tests",
    ],
)

rollup_bundle(
    name = "bundle",
    entry_point = "entry.ts",
    deps = [":entry_lib"],
)

concat(
    name = "extension",
    srcs = [
        # Order matters here.
        "polyfill.js",
        "setup.js",
        "bundle.js",
    ],
    out = "extension.js",
)