SConscript

# -*- python -*-
# $Id$
# Authors: James Peachey <peachey@lheamail.gsfc.nasa.gov>, Joe Asercion <joseph.a.asercion@nasa.gov>
# Version: st_graph-01-07-11

Import('baseEnv')
Import('listFiles')
progEnv = baseEnv.Clone()
libEnv = baseEnv.Clone()
if baseEnv['PLATFORM'] == "posix":
    libEnv.Append(CPPDEFINES = 'TRAP_FPE')

includeFiles = listFiles(["st_graph/*"], recursive=True)

if libEnv.get('CONTAINERNAME', '') == 'ScienceTools_User':
    st_graphRootcint = libEnv.Rootcint('st_graph/st_graph_rootcint',
                                       ['st_graph/RootFrame.h',
                                        'st_graph/LinkDef.h'],
                                       includes = ['.', 'src'],
                                       localIncludes=includeFiles,
                                       packageName='st_graph')
    st_graphLib = libEnv.StaticLibrary('st_graph', listFiles(['src/*.cxx']) + ['st_graph/st_graph_rootcint.cxx'] + ['src/EmbedPython.cpp'])
else:
    st_graphLib = libEnv.StaticLibrary('st_graph', 
                                       listFiles(['src/Axis.cxx', 
                                                  'src/EmbedPython.cpp',
                                                  'src/Engine.cxx', 
                                                  'src/IPlot.cxx',
                                                  'src/MP*.cxx', 
                                                  'src/StGui.cxx']))

progEnv.Tool('st_graphLib')
if baseEnv['PLATFORM'] == "posix":
    progEnv.Append(CPPDEFINES = 'TRAP_FPE')

test_st_graphBin = progEnv.Program('test_st_graph', listFiles(['src/test/*.cxx']))

progEnv.Tool('registerTargets', package = 'st_graph',
             staticLibraryCxts = [[st_graphLib,libEnv]],
             includes = listFiles(['st_graph/*.h']),
             testAppCxts = [[test_st_graphBin, progEnv]],
             pfiles = listFiles(['pfiles/*.par']),
             python=listFiles(['src/*.py']))