Atbash Cipher Error

[Koch013]

I receive the following error while running the tests online:

./zcl_atbash_cipher.clas.abap[50, 5] - "txt_len" not found, findTop (check_syntax) [E]
abaplint: 1 issue(s) found

Here's my code, which works fine on my local system:

CLASS zcl_atbash_cipher DEFINITION PUBLIC FINAL CREATE PUBLIC.

  PUBLIC SECTION.
    METHODS decode
      IMPORTING
        cipher_text TYPE string
      RETURNING
        VALUE(plain_text)  TYPE string .
    METHODS encode
      IMPORTING
        plain_text        TYPE string
      RETURNING
        VALUE(cipher_text) TYPE string .
  PROTECTED SECTION.
  PRIVATE SECTION.
ENDCLASS.



CLASS zcl_atbash_cipher IMPLEMENTATION.

  METHOD decode.
   plain_text =  translate( val = |{ condense( val = to_lower( cipher_text ) from = ` ,.:;` TO = `` )  }|
                              from = |{ REVERSE( to_lower( sy-abcde ) ) && `0123456789` }|
                              to = |{ to_lower( sy-abcde ) && `0123456789` }|
                               ).
  ENDMETHOD.

  METHOD encode.
    cipher_text =  translate( val = |{ condense( val = to_lower( plain_text ) from = ` ,.:;` TO = `` )  }|
                              from = |{ to_lower( sy-abcde ) && `0123456789` }|
                              TO = |{ REVERSE( to_lower( sy-abcde ) ) && `0123456789` }| ).
    cipher_text = REDUCE string( LET txt_len = STRLEN( cipher_text ) IN
                            INIT text = `` offset = 0 sep = ``
                            FOR i = 1 UNTIL i > round( val = ( txt_len / 5 ) dec = 0 mode = cl_abap_math=>round_up )
                            NEXT text = text && sep &&
                                       substring( val = cipher_text off = offset
                                       len = nmin( val1 = 5
                                                   val2 = txt_len - offset )
                                                )
                                 sep = ` ` offset = i * 5 ).

  ENDMETHOD.

ENDCLASS.

[larshp]

thanks 👍

[larshp]

reproduced as

DATA(text) = REDUCE string(
  LET txt_len = strlen( |dfsdfs| ) IN
  INIT foo = ``
  FOR i = 1 UNTIL i > txt_len
  NEXT foo = foo && |sdf| ).

[larshp]

abaplint/abaplint@24a7b23

[larshp]

next problem: the downport ignores txt_len

[larshp]

abaplint/abaplint@9bc9ab8

open-abap/open-abap-core#312
exercism/abap-test-runner#100

[larshp]

abaplint/transpiler#726

[larshp]

now got 6 passing,

[larshp]

@Koch013 try again

[Koch013]

Works now, thanks!