-
Notifications
You must be signed in to change notification settings - Fork 1
/
build.gradle
192 lines (165 loc) · 5.48 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
plugins {
id 'com.github.ben-manes.versions' version '0.44.0'
id 'scala'
id 'signing'
id 'com.gradle.plugin-publish' version '1.2.1'
id 'org.podval.tools.scalajs' version '0.4.12' // Note: must be applied *after* Plugin Portal Plugin
}
group = 'org.podval.tools'
version = '0.4.12'
description = 'Gradle plugin for ScalaJS'
final String scalaVersion = '3.4.2'
final String scala2versionMinor = '2.13'
final String scalaJsVersion = '1.16.0'
final String sbtVersion = '1.10.0'
dependencies {
implementation "org.scala-lang:scala3-library_3:$scalaVersion"
// used: Gradle, DependencyRequirement, Node
implementation 'org.opentorah:opentorah-util:0.10.12'
zinc "org.scala-sbt:zinc_$scala2versionMinor:$sbtVersion"
compileOnly 'org.scala-sbt:test-interface:1.0'
// Note: transitive dependencies: zinc-persist -> zinc-core -> zinc-apiinfo, io, compiler-interface
compileOnly "org.scala-sbt:zinc-persist_$scala2versionMinor:$sbtVersion"
compileOnly "org.scala-js:scalajs-linker_$scala2versionMinor:$scalaJsVersion"
compileOnly "org.scala-js:scalajs-sbt-test-adapter_$scala2versionMinor:$scalaJsVersion"
compileOnly "org.scala-js:scalajs-env-jsdom-nodejs_$scala2versionMinor:1.1.0"
// For framework-specific exceptions
compileOnly 'junit:junit:4.13.2'
compileOnly 'org.scalatest:scalatest_3:3.2.18'
compileOnly 'org.scalacheck:scalacheck_3:1.18.0'
compileOnly 'com.lihaoyi:utest_3:0.8.3'
compileOnly 'org.specs2:specs2-core_3:5.5.3'
compileOnly 'org.scalameta:munit_3:1.0.0'
// TODO ZIO Test
testImplementation 'org.scalatest:scalatest_3:3.2.18'
// TODO - was...
// // Used for running the GradleRunner tests in the testNg task -
// // and to compare my integration with Gradle and Idea with the real one :)
// testImplementation 'org.testng:testng:7.7.1'
}
//tasks.register('testNg', Test) {
// setGroup("verification")
// useTestNG()
//}
java.toolchain.languageVersion = JavaLanguageVersion.of(11)
tasks.withType(ScalaCompile).configureEach {
scalaCompileOptions.with {
additionalParameters = [
'-new-syntax',
'-feature',
'-language:strictEquality'
// '-source:future'
]
}
}
jar {
manifest {
attributes(
'Implementation-Title' : project.description,
'Implementation-Version': project.version
)
}
}
tasks.register('sourcesJar', Jar) {
from sourceSets.main.allSource
archiveClassifier.set('sources')
}
tasks.register('scaladocJar', Jar) {
from scaladoc.destinationDir
archiveClassifier.set('scaladoc')
}
scaladocJar.dependsOn scaladoc
// There is no Java in the project :)
project.gradle.startParameter.excludedTaskNames.add('compileJava')
// but Maven Central requires javadoc JAR...
tasks.register('javadocJar', Jar) {
from javadoc.destinationDir
archiveClassifier.set('javadoc')
}
javadocJar.dependsOn(javadoc)
final String gitHubRepository = "dubinsky/scalajs-gradle"
final String gitHubRepositoryUrl = "https://github.com/$gitHubRepository"
final String orgName = 'Podval Group'
final String orgUrl = 'https://www.podval.org'
publishing {
repositories {
maven {
name = 'mavenCentral'
url = version.endsWith('SNAPSHOT') ?
'https://oss.sonatype.org/content/repositories/snapshots' :
'https://oss.sonatype.org/service/local/staging/deploy/maven2'
// Note: this will use mavenCentralUsername and mavenCentralPassword properties - if they are available
credentials(PasswordCredentials)
}
}
publications {
library(MavenPublication) {
from components.java
artifact sourcesJar
artifact scaladocJar
artifact javadocJar
pom {
name = project.name
description = project.description
url = gitHubRepositoryUrl
scm {
url = gitHubRepositoryUrl
connection = "scm:git:git://github.com/${gitHubRepository}.git"
developerConnection = "scm:git:ssh://github.com/${gitHubRepository}.git"
}
licenses {
license {
name = 'The Apache Software License, Version 2.0'
url = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
distribution = 'repo'
comments = 'A business-friendly OSS license'
}
}
organization {
name = orgName
url = orgUrl
}
developers {
developer {
id = 'dub'
name = 'Leonid Dubinsky'
email = '[email protected]'
url = 'https://dub.podval.org'
organization = orgName
organizationUrl = orgUrl
timezone = '-5'
}
}
}
}
}
}
signing {
sign publishing.publications.library
useInMemoryPgpKeys(
findProperty('gnupg.dub-podval-org.key').toString(),
findProperty('gnupg.dub-podval-org.password').toString()
)
}
gradlePlugin {
website = gitHubRepositoryUrl
vcsUrl = gitHubRepositoryUrl //.git' ?
plugins {
scalajs {
id = 'org.podval.tools.scalajs'
implementationClass = 'org.podval.tools.scalajs.ScalaJSPlugin'
displayName = project.description
description = project.description
tags.set(['Scala', 'ScalaJS', 'sbt', 'testing', 'ScalaTest'])
}
}
}
tasks.register('uploadLibrary')
uploadLibrary.description('Upload artifacts')
uploadLibrary.group('publishing')
uploadLibrary.dependsOn(publishLibraryPublicationToMavenCentralRepository)
tasks.register('upload')
upload.description('Upload artifacts and plugins')
upload.group('publishing')
upload.dependsOn(uploadLibrary)
upload.dependsOn(publishPlugins)