build.gradle

plugins {
	id 'dev.architectury.loom' version '1.3-SNAPSHOT'
	id "io.github.p03w.machete" version "2.+"
	id 'maven-publish'
}

loom {
	forge {
		mixinConfigs = [
				"mixins.blur.json"
		]
	}
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
	maven {
		name = 'ConstructLegacy'
		url = 'https://repo.constructlegacy.ru/public'
		content {
			includeGroup 'com.github.dima_dencep.mods'
		}
	}
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	forge "net.minecraftforge:forge:${project.loader_version}"

	modImplementation include("com.github.dima_dencep.mods:satin-forge:${satin_version}")
}

processResources {
	inputs.property "version", project.version

	filesMatching("META-INF/mods.toml") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
	it.options.release = 17
}

java {
	withSourcesJar()
}

jar {
	from "LICENSE"
}

machete {
	ignoredTasks.add("shadowJar")
	ignoredTasks.add("jar")
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}
}