build.gradle

import org.gradle.internal.os.OperatingSystem

plugins {
	id 'java'
	id 'application'
}

mainClassName = 'chess_game.Main'

dependencies {
	def lwjglVersion = '3.1.1'
	def platform

	def os = OperatingSystem.current()
	if (os.isWindows())
		platform = 'windows'
	else if (os.isLinux())
		platform = 'linux'
	else if (os.isMacOsX())
		platform = 'macos'
	else
		throw new GradleException("Unknown operating system '" + os + "'.\nNeeds to be either Windows, Linux or macOS.")
	println "Platform detected to be '" + platform + "'."

	implementation group: 'org.lwjgl', name: 'lwjgl', version: lwjglVersion
	implementation group: 'org.lwjgl', name: 'lwjgl-glfw', version: lwjglVersion
	implementation group: 'org.lwjgl', name: 'lwjgl-opengl', version: lwjglVersion
	implementation group: 'org.lwjgl', name: 'lwjgl-stb', version: lwjglVersion

	runtime group: 'org.lwjgl', name: 'lwjgl', version: lwjglVersion, classifier: 'natives-' + platform
	runtime group: 'org.lwjgl', name: 'lwjgl-glfw', version: lwjglVersion, classifier: 'natives-' + platform
	runtime group: 'org.lwjgl', name: 'lwjgl-opengl', version: lwjglVersion, classifier: 'natives-' + platform
	runtime group: 'org.lwjgl', name: 'lwjgl-stb', version: lwjglVersion, classifier: 'natives-' + platform

	implementation 'org.joml:joml:1.9.2'
}

sourceSets {
	main {
		java {
			srcDirs = ['src/main/java']
		}
		resources {
			srcDirs = ['src/main/resources']
		}
	}
}

repositories {
	jcenter()
}