build.gradle

buildscript {
	repositories {
		mavenCentral()
	}
	dependencies { classpath ('com.vladsch.flexmark:flexmark-all:0.19.3') }
}

plugins {
	id 'java'
	id 'application'
	id 'maven-publish'
	id 'signing'
	id 'org.ajoberstar.grgit' version '3.1.1'
}

mainClassName = "application.ui.MainFx"
compileJava.options.encoding = 'UTF-8'
compileTestJava.options.encoding = 'UTF-8'
javadoc {
	options.encoding = 'UTF-8'
	options.source = 8
	options.links('https://docs.oracle.com/javase/8/docs/api/');
}
sourceCompatibility = '1.8'
targetCompatibility = '1.8'
 
def repoRevision = grgit.status().clean ? grgit.head().getId() 
			: (System.getenv("REPO_REVISION")!=null ? System.getenv("REPO_REVISION") : repositoryRevision)

group = "org.daisy.dotify"

sourceSets {
	main {
		java {
			srcDir 'src'
		}
		resources {
			srcDir 'src'
		}
	}
	test {
		java {
			srcDir 'test'
		}
		resources {
			srcDir 'test'
		}
	}
}

jar {
	doFirst {
		manifest {
	    	attributes ('Built-By': System.getProperty("user.name"),
	    	'Built-On': new Date().format("yyyy-MM-dd"),
			'Repository-Revision': "$repoRevision",
			'Implementation-Title': "$releaseName",
			'Implementation-Version': archiveVersion,
			'Implementation-URL': "$repositoryURL",
			'Main-Class': 'application.ui.MainFx',
			'Class-Path': configurations.runtimeClasspath.collect { it.getName() }.join(' ')
			)
		}
	}
	from sourceSets.main.allJava
}

repositories {
    mavenCentral()
    //mavenLocal()
    maven { url "https://oss.sonatype.org/content/groups/staging" }
    //maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
}

dependencies {
	compileOnly 'org.osgi:org.osgi.service.component.annotations:1.3.0'

	implementation ('org.daisy.braille:braille-utils.pef-tools:6.0.0') {
		exclude module: 'Saxon-HE'
	}
	implementation 'com.googlecode.ajui:ajui:1.0.0'
	
	implementation 'org.daisy.dotify:dotify.api:5.0.0'
	implementation 'org.daisy.streamline:streamline-api:1.6.0'
	implementation 'org.daisy.dotify:dotify.common:4.4.0'
	implementation ('org.daisy.streamline:streamline-engine:1.3.0') {
		exclude module: 'streamline-api'
	}
	implementation 'org.fxmisc.richtext:richtextfx:0.10.5'
	
	testImplementation group: 'junit', name: 'junit', version: "4.12"
	
	runtimeOnly 'org.slf4j:slf4j-jdk14:1.7.2'
	runtimeOnly ('org.daisy.dotify:dotify.formatter.impl:5.0.1') {
		exclude module: 'Saxon-HE'
	}
	runtimeOnly 'org.daisy.dotify:dotify.hyphenator.impl:5.0.0'
	runtimeOnly 'org.daisy.dotify:dotify.text.impl:5.0.0'
	runtimeOnly 'org.daisy.dotify:dotify.translator.impl:5.1.0'
	runtimeOnly ('org.daisy.dotify:dotify.task.impl:5.0.0') {
		exclude module: 'Saxon-HE'
	}
	runtimeOnly 'org.daisy.braille:braille-utils.impl:7.0.0'

	runtimeOnly ('org.daisy.streamline:format-catalog:1.2.0') {
		exclude module: 'streamline-api'
	}
	
	runtimeOnly ('org.daisy.dotify:docs-to-html:1.0.0') {
		exclude module: 'streamline-api'
	}

}

task copyDocResources(type: Copy) {
	from ('docs') {
		include('**/*.png')
		include('**/*.css')
	}
	into ('build/docs/man')
}

task convertDocs(dependsOn: ['copyDocResources']) {
	def outputDir = file('build/docs/man')
	def inputDir = file('docs')
	inputs.dir inputDir
	outputs.dir outputDir
	doLast() {
	    def options = new com.vladsch.flexmark.util.options.MutableDataSet().set(
		    			com.vladsch.flexmark.parser.Parser.EXTENSIONS,
		    			Arrays.asList(
		    				com.vladsch.flexmark.ext.autolink.AutolinkExtension.create(),
		    				com.vladsch.flexmark.ext.gfm.strikethrough.StrikethroughExtension.create(),
		    				com.vladsch.flexmark.ext.wikilink.WikiLinkExtension.create()
		    			)
	    			).set(
	    				com.vladsch.flexmark.ext.wikilink.WikiLinkExtension.LINK_FILE_EXTENSION,
	    				".html"
	    			)

	    def parser = com.vladsch.flexmark.parser.Parser.builder(options).build()
	    def renderer = com.vladsch.flexmark.html.HtmlRenderer.builder(options).build()
		def inputEncoding = 'UTF-8'
		def outputEncoding = 'UTF-8'
		def language = 'en'
		outputDir.mkdirs()
		fileTree(dir: inputDir, include: '*.md')
			.filter{it.isFile()}
			.each {
				file("${outputDir}/${it.name[0..-4]}.html").write(
					"<?xml version=\"1.0\" encoding=\""
					+ outputEncoding+"\"?>\n<html xmlns=\"http://www.w3.org/1999/xhtml\" xml:lang=\""
					+ language+"\">\n<head>\n<meta charset=\""
					+ outputEncoding+"\"/>\n<link rel=\"stylesheet\" type=\"text/css\" href=\"styles/style.css\">\n</head>\n<body>"
					+ renderer.render(parser.parse(it.getText(inputEncoding)))
					+ "</body>\n</html>", outputEncoding
				)
			}
	}
}

distributions {
    main {
        contents {
            from(convertDocs) {
                into "docs"
            }
            from(file('installer/examples')) {
            	into 'examples'
            }
        }
    }
}

task javadocJar(type: Jar) {
	classifier = 'javadoc'
	from javadoc
}

task sourcesJar(type: Jar) {
	classifier = 'sources'
	from sourceSets.main.allSource
}

ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

signing {
	required { isReleaseVersion }
	sign publishing.publications
}

publishing {
	//Only upload if a git hash is supplied. On Travis only upload snapshots.
	//enabled = repoRevision.size()==40 && System.getenv("TRAVIS_BUILD_ID")!=null
	publications {
		maven(MavenPublication) {
			from components.java
			artifact sourcesJar
			artifact javadocJar
			artifact distZip
			artifact distTar
			/*
			if (isReleaseVersion) {
				beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
			}*/
			pom {
				name = 'dotify-studio'
				packaging = 'jar'
				description = 'Dotify Studio'
				url = "$repositoryURL"
				scm {
					connection = "$repositorySCM"
					developerConnection = "$repositorySCM"
					url = "$repositoryURL"
				}
				licenses {
					license {
						name = 'LGPL'
						url = 'http://www.gnu.org/licenses/lgpl.html'
					}
				}
				developers {
					developer {
						id = 'joel'
						name = 'Joel Håkansson'
					}
				}
			}
		}
	}
	repositories {
		maven {
			def stagingRepoUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
			def snapshotsRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
			url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : stagingRepoUrl
			credentials {
				username = sonatypeUsername
				password = sonatypePassword
			}
		}
	}
}

wrapper {
    distributionType = Wrapper.DistributionType.ALL
}