build.gradle

//file:noinspection GroovyAssignabilityCheck
//file:noinspection GrUnresolvedAccess

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'jacoco'
}

repositories {
    mavenLocal()
    maven {
        url = uri('https://repo.maven.apache.org/maven2/')
    }
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.9.1'
}

group = 'org.behrang.algorithm'
version = '1.0-SNAPSHOT'
description = 'John Q Walker Node Positioning Algorithm'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/behrangsa/walker-algorithm")
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("USERNAME")
                password = project.findProperty("gpr.key") ?: System.getenv("TOKEN")
            }
        }
    }

    publications {
        gpr(MavenPublication) {
            from(components.java)
        }
    }
}

test {
    useJUnitPlatform()
    finalizedBy jacocoTestReport
}

jacocoTestReport {
    dependsOn test
}