Jenkinsfile.disabled

pipeline {
    agent any
    triggers {
        // Build/deploy master at noon and 6pm PT.
        cron(env.BRANCH_NAME == 'master' ? '0 2,20 * * *' : '')
    }
    options {
        buildDiscarder(logRotator(numToKeepStr:'10'))
        timeout(time: 15, unit: 'MINUTES')
        ansiColor('xterm')
    }
    environment { 
        GATSBY_JAZZ_URL = credentials('GATSBY_JAZZ_URL') 
    }
    stages {
        stage('Build pull requests') {
            when { changeRequest() }
            steps {
                script {
                    // Build new image.
                    sh "docker build -t \"civicactions-internal-it/home:${env.CHANGE_ID}\" --build-arg \"GATSBY_JAZZ_URL=${GATSBY_JAZZ_URL}\" --pull ."
                    // Remove existing container if it is running.
                    sh "docker rm -f \"home-${env.CHANGE_ID}\" || true"
                    // Start container with the right hostname.
                    sh "docker run --detach --rm --name=\"home-${env.CHANGE_ID}\" \"civicactions-internal-it/home:${env.CHANGE_ID}\""
                    slackSend channel: 'homesite-bots', message: "PR Review environment ready at http://home-${env.CHANGE_ID}.ci.civicactions.net/"
                }
            }
        }
        stage('Build master branch') {
            when { branch 'master' }
            steps {
                script {
                    // Add a timestamp file to ensure we rebuild the site content
                    sh "date > .build-timestamp"
                    docker.withRegistry('https://gcr.io', 'internal-it-k8s-gcr') {
                        def latestImage = docker.build("civicactions-internal-it/home", "--build-arg GATSBY_JAZZ_URL=${GATSBY_JAZZ_URL} --pull .")
                        latestImage.push("latest")
                        latestImage.push("${env.GIT_COMMIT}-${env.BUILD_NUMBER}")
                        slackSend channel: 'homesite-bots', message: "Master branch built and image pushed successfully to Docker registry"
                    }
                }
            }
        }
    }
    post {
        failure {
            slackSend channel: 'homesite-bots', message: "Build failed, see build log for details: ${env.BUILD_URL}console"
        }
    }
}