From 3cf8cb16ebc829c11fc9840a34bcdc67449962f2 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
Date: Sun, 3 Apr 2022 19:36:06 +0200
Subject: [PATCH] upower: upgrade 0.99.13 -> 0.99.17 / build with mesom
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Port to meson turned into total overhaul of recipe

Version 0.99.17
---------------
Released: 2022-03-09

Bug fixes:
- Fix FD handling issues that may cause lid to not be detected

Version 0.99.16
---------------
Released: 2022-02-23

Bug fixes:
- Silence unnecessary udev event warnings
- Increase test timeout (#171)
- Explicitly link with plist
- Fix UpClient reference leak
- Fix DisplayDevice state on battery hotplug
- Fix critical action to work after it was cancelled (#172)

Version 0.99.15
---------------
Released: 2022-02-09

Bug fixes:
- Various build fixes
- Update bluetooth device alias when it changes (#169)

No info for 0.99.14

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 .../recipes-support/upower/upower_0.99.13.bb  | 38 ----------------
 .../recipes-support/upower/upower_0.99.17.bb  | 44 +++++++++++++++++++
 2 files changed, 44 insertions(+), 38 deletions(-)
 delete mode 100644 meta-oe/recipes-support/upower/upower_0.99.13.bb
 create mode 100644 meta-oe/recipes-support/upower/upower_0.99.17.bb

diff --git a/meta-oe/recipes-support/upower/upower_0.99.13.bb b/meta-oe/recipes-support/upower/upower_0.99.13.bb
deleted file mode 100644
index 55a7354820d..00000000000
--- a/meta-oe/recipes-support/upower/upower_0.99.13.bb
+++ /dev/null
@@ -1,38 +0,0 @@
-DESCRIPTION = "UPower is an abstraction for enumerating power devices, listening to device events and querying history and statistics. "
-LICENSE = "GPL-2.0-or-later"
-LIC_FILES_CHKSUM = "file://COPYING;md5=0de8fbf1d97a140d1d93b9f14dcfbf08"
-
-DEPENDS = "intltool-native libusb1 libgudev glib-2.0 dbus-glib"
-
-SRC_URI = "git://gitlab.freedesktop.org/upower/upower.git;protocol=https;branch=master"
-SRCREV = "0f6cc0a10be22d7ddd684e1cd851e4364a440494"
-S = "${WORKDIR}/git"
-
-UPSTREAM_CHECK_GITTAGREGEX = "UPOWER_(?P<pver>\d+(\_\d+)+)"
-
-inherit autotools pkgconfig gtk-doc gettext gobject-introspection systemd
-
-PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
-PACKAGECONFIG[idevice] = "--with-idevice,--without-idevice,libimobiledevice libplist"
-PACKAGECONFIG[systemd] = "--with-systemdutildir=${systemd_unitdir} --with-systemdsystemunitdir=${systemd_system_unitdir}, \
-                          --without-systemdutildir --without-systemdsystemunitdir,systemd"
-
-EXTRA_OECONF = " --with-backend=linux"
-
-SYSTEMD_SERVICE:${PN} = "upower.service"
-# don't start on boot by default - dbus does that on demand
-SYSTEMD_AUTO_ENABLE = "disable"
-
-do_configure:prepend() {
-    touch ${S}/ABOUT-NLS
-    mkdir -p ${S}/build-aux
-    touch ${S}/build-aux/config.rpath
-    sed -i -e s:-nonet:\:g ${S}/doc/man/Makefile.am
-    sed -i -e 's: doc : :g' ${S}/Makefile.am
-}
-
-RDEPENDS:${PN} += "dbus"
-RRECOMMENDS:${PN} += "pm-utils"
-FILES:${PN} += "${datadir}/dbus-1/ \
-                ${base_libdir}/udev/* \
-"
diff --git a/meta-oe/recipes-support/upower/upower_0.99.17.bb b/meta-oe/recipes-support/upower/upower_0.99.17.bb
new file mode 100644
index 00000000000..d30fcea8715
--- /dev/null
+++ b/meta-oe/recipes-support/upower/upower_0.99.17.bb
@@ -0,0 +1,44 @@
+SUMMARY = "UPower is an abstraction for enumerating power devices"
+DESCRIPTION = "UPower is an abstraction for enumerating power devices, listening to device events and querying history and statistics."
+LICENSE = "GPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=0de8fbf1d97a140d1d93b9f14dcfbf08"
+
+DEPENDS = " \
+    intltool-native \
+    libusb1 \
+    libgudev \
+    glib-2.0 \
+    dbus-glib \
+"
+
+SRC_URI = "git://gitlab.freedesktop.org/upower/upower.git;protocol=https;branch=master"
+SRCREV = "c889154ec8e3e2239db9260d48b2e198d72ba002"
+S = "${WORKDIR}/git"
+
+UPSTREAM_CHECK_GITTAGREGEX = "UPOWER_(?P<pver>\d+(\_\d+)+)"
+
+GIR_MESON_ENABLE_FLAG = "enabled"
+GIR_MESON_DISABLE_FLAG = "disabled"
+GTKDOC_MESON_OPTION = "gtk-doc"
+
+inherit meson pkgconfig gtk-doc gettext gobject-introspection systemd
+
+PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
+PACKAGECONFIG[idevice] = "-Didevice=enabled,-Didevice=disabled,libimobiledevice libplist"
+PACKAGECONFIG[systemd] = "-Dsystemdsystemunitdir=${systemd_system_unitdir},-Dsystemdsystemunitdir=no,systemd"
+
+EXTRA_OEMESON = " \
+    -Dos_backend=linux \
+    -Dman=false \
+"
+
+SYSTEMD_SERVICE:${PN} = "upower.service"
+# don't start on boot by default - dbus does that on demand
+SYSTEMD_AUTO_ENABLE = "disable"
+
+RDEPENDS:${PN} += "dbus"
+RRECOMMENDS:${PN} += "pm-utils"
+FILES:${PN} += " \
+    ${datadir}/dbus-1/ \
+    ${base_libdir}/udev/* \
+"