Prog Assist.bat

@echo off
mode con: cols=49 lines=30
title Programming Assistant
setlocal EnableDelayedExpansion
echo Loading . . .
Set version=Release-1.6
set autostart=on
set dontdisplaytrs=FALSE
if exist Bin\Settings.cmd call Bin\Settings.cmd
if %autostart%==on (
	call Bin\CMDS.bat /ts "Prog Assistant COM Companion"
	if !errorlevel!==1 cscript //B //Nologo "Bin\CMS.vbs"
)
REM TODO
rem 4. add auto github check on new vendor model

ping github.com -n 1 >nul 2>nul
if %errorlevel%==0 call :CheckForUpdates
:CancelUpdate
set lines=10
goto mainmenu

:titlebar
echo F1-Menu F2-Updates F3-New Window F4-COMS F10-Quit
echo =================================================
exit /b

:Menutitlebar
echo F1-Menu F2-Updates F3-New Window F4-COMS F10-Quit
echo =================================================
exit /b

:mainmenu
cls
echo =================================================
call :Menutitlebar
if exist Bin\logo.ascii (
    type Bin\logo.ascii
	echo.
)
echo =================================================
echo 1] View Radio
echo 2] New Radio
echo 3] COM Ports
echo S] Settings
echo U] Update Vendors, Radios, ^& Cables Online
echo X] Exit
"Bin\kbd.exe"
if %errorlevel%==49 goto ViewRadio
if %errorlevel%==50 goto AddRadio
if %errorlevel%==51 goto COMS
if %errorlevel%==51 exit /b
if %errorlevel%==120 exit /b
if %errorlevel%==59 goto mainmenu
if %errorlevel%==60 goto Updates
if %errorlevel%==61 start "" "%~0"
if %errorlevel%==62 goto COMS
if %errorlevel%==115 goto settings
if %errorlevel%==52 goto settings
if %errorlevel%==117 goto updates
if %errorlevel%==68 exit /b
goto mainmenu


:updates
:UpdateLibrary
cls
if exist Bin\logo.ascii (
    type Bin\logo.ascii
	echo.
)
echo =================================================
set owner=W1BTR
set Didupdate=No
set repo=Programming-Assistant
echo Checking repository for new vendors and radios...
:: Get the JSON data from GitHub API and save it to a temporary file
curl -s -H "Accept: application/vnd.github.v3.raw" -L https://api.github.com/repos/%OWNER%/%REPO%/contents/Bin/Files/Vendors > temp.json
:: Use PowerShell to parse the JSON and output the names
for /f "delims=" %%i in ('powershell -Command "Get-Content temp.json | ConvertFrom-Json | ForEach-Object { $_.name }"') do (
    if not exist "Bin\Files\Vendors\%%~i" (
        echo. > "Bin\Files\Vendors\%%~i"
        echo Added new Vendor: %%~i
		set Didupdate=Yes
    )
    set Vendor=%%~i
    set VendorURL=!Vendor: =%%20!
    curl -s -H "Accept: application/vnd.github.v3.raw" -L https://api.github.com/repos/%OWNER%/%REPO%/contents/Bin/Files/Radios/!VendorURL! > "vendortemp.json"
    for /f "delims=" %%l in ('powershell -Command "Get-Content vendortemp.json | ConvertFrom-Json | ForEach-Object { $_.name }"') do (
        if not exist "Bin\Files\Radios\!Vendor!\%%~l" (
            if not exist "Bin\Files\Radios\!vendor!" md "Bin\Files\Radios\!vendor!\"
            set Radio=%%~l
            set Radio=!Radio: =%%20!
            curl -# -H "Accept: application/vnd.github.v3.raw" -L https://api.github.com/repos/%OWNER%/%REPO%/contents/Bin/Files/Radios/!vendorURL!/!Radio! -o "Bin\Files\Radios\!vendor!\%%~l"
			echo Added New Radio: %%~nl
			set Didupdate=Yes
        )
    )
)

echo Checking repository for new cables...
del /f /q vendortemp.json
curl -s -H "Accept: application/vnd.github.v3.raw" -L https://api.github.com/repos/%OWNER%/%REPO%/contents/Bin/Files/Cables > temp.json
for /f "delims=" %%l in ('powershell -Command "Get-Content temp.json | ConvertFrom-Json | ForEach-Object { $_.name }"') do (
    if /i not "%%~l"=="Owned" (
        if not exist "Bin\Files\Cables\%%~l" (
            set CableURL=%%~l
            set CableURL=!CableURL: =%%20!
            curl -# -H "Accept: application/vnd.github.v3.raw" -L https://api.github.com/repos/%OWNER%/%REPO%/contents/Bin/Files/Cables/!CableURL! -o "Bin\Files\Cables\%%~l"
            echo Added New Cable: %%~nl
			set Didupdate=Yes
        )
    )
)

:: Clean up temporary file
del temp.json
if %didupdate%==Yes (
	echo Updates Installed.
) ELSE (
	echo Library was up to date.
)
pause
goto mainmenu


:CheckForUpdates
set OWNER=W1BTR
set REPO=Programming-Assistant
curl -s -H "Accept: application/vnd.github.v3+json" -L https://api.github.com/repos/%OWNER%/%REPO%/releases/latest | find /i "%version%" >nul 2>nul
if %errorlevel%==0 exit /b
cls
echo An Update is Available.
curl -s -H "Accept: application/vnd.github.v3.raw" -L https://api.github.com/repos/%OWNER%/%REPO%/contents/Bin/Release.bat -o Release.bat
call Release.bat Info
echo Run Update now?
choice
if %errorlevel%==2 goto CancelUpdate
echo Installing update . . .
call Release.bat Install
echo Update failed.
pause
goto CancelUpdate


:settings
if %autostart%==on (
	set ascolor=
) ELSE (
	set ascolor=
)
cls
echo Settings Menu
echo --------------------
echo 1] COM Assistant Autostart: [%ascolor%%autostart%]
echo X] Exit
choice /c 1x
if %errorlevel%==1 (
	if %autostart%==on (
		set autostart=off
		goto savesettings
	) ELSE (
		set autostart=on
		goto savesettings
	)
)
goto mainmenu

:savesettings
(echo set autostart=%autostart%)>Bin\settings.cmd

goto settings

:COMS
set check=30
set selectedPort=1
if %autostart%==off (
	call Bin\CMDS.bat /ts "Prog Assistant COM Companion"
	if !errorlevel!==1 cscript //B //Nologo "Bin\CMS.vbs"
)
:COMLoop
set num=0
set linecount=0
cls
if not exist "Bin\COMLOG.log" goto :loadCOMLOG
call :menutitlebar
if exist Bin\logo.ascii (
    type Bin\logo.ascii
	echo.
)
echo =================================================
echo.
echo COM PORTS:
for /f "tokens=1,2,3 delims=, skip=1" %%A in ('type "Bin\COMLOG.log"') do (
	set /a linecount+=1
	set /a num+=1
	set COMPort!num!=%%~A
	set descrp=%%~B
	if "!num!"=="!SelectedPort!" (
		set comcolor=
	) ELSE (
		set comcolor=
	)
	if "%%~C"=="True" (
		echo !comcolor!%%~A !comcolor!!descrp:~0,38! NEW
	) ELSE (
		echo !comcolor!%%~A  !comcolor!!descrp:~0,38!
	)
)
copy /y "Bin\COMLOG.log" "Bin\COMLog.diff" >nul 2>nul
set check=30
:comKBDLoop
"Bin\Kbd.exe" 1
set /a check-=1
if %check%==0 (
	fc "Bin\COMLOG.diff" "Bin\ComLog.log" >nul 2>nul
	if !errorlevel!==1 goto COMLoop
	set check=30
	goto comKBDLoop
)
if %errorlevel%==0 goto comKBDLoop
if %errorlevel%==110 goto newvendor
if %errorlevel%==27 goto comstomainmenu
if %errorlevel%==120 goto comstomainmenu
if %errorlevel%==59 goto comstomainmenu
if %errorlevel%==60 goto Updates
if %errorlevel%==61 start "" "%~0"
if %errorlevel%==62 goto COMS
if %errorlevel%==68 exit /b
set _errorlevel=%errorlevel%
rem if %_errorlevel%==59 goto options
if %_errorlevel%==80 (
	if not !SelectedPort! GEQ !linecount! (
		set /a SelectedPort+=1
	)
)
if %_errorlevel%==72 (
	if not !SelectedPort! LEQ 1 (
		set /a SelectedPort-=1
	)
)
if %_errorlevel%==13 goto SelectedCOM
goto comloop

:loadCOMLOG
echo Loading . . .
:loadcomlogloop
if not exist "Bin\COMLOG.log"  goto loadcomlogloop
goto comloop

:comstomainmenu
if %autostart%==off (
	call Bin\CMDS.bat /tk "Prog Assistant COM Companion"
)
goto mainmenu

:SelectedCOM
cls
mode !COMPort%SelectedPort%! | more
mode !COMPort%SelectedPort%! | find /i "Not Available" >nul 2>nul
if %errorlevel%==1 (
	echo 1] Change Setting [Baud, Parity, XON, etc]
	echo 2] Enter Text Data into Port
	echo 3] View Text Output
	echo 4] Start a Putty Session
	echo 5] Open Putty
	echo 6] Pipe to Virtual Port [For Hypervisor]
	echo X] Back
) ELSE (
	echo X] Back
)
choice /c 123456X /n

if %errorlevel%==4 (
	putty -serial !COMPort%SelectedPort%!
	goto selectedcom
)
if %errorlevel%==5 (
	putty -serial
	goto selectedcom
)
if %errorlevel%==1 goto comsetting
if %errorlevel%==2 goto DataPort
if %errorlevel%==3 goto TypePort
if %errorlevel%==6 goto passthrough
goto COMS

:passthrough
if "%baudrate%"=="" set baudrate=19200
if "%PipeName%"=="" set PipeName=MyLittlePipe
cls
echo COM PIPE [howardtechnical.com] !COMPort%SelectedPort%!
echo NOTE: This tool cannot create a named pipe,
echo it can only use an existing named pipe otherwise
echo a GLE error will occur.
echo.
echo 1] Change Baud Rate [%baudrate%]
echo 2] Change Pipe Name [\\.\pipe\%PipeName%\]
echo 3] START PIPE
echo X] Cancel
choice /c 123x
if %errorlevel%==1 (
	echo.
	echo Enter BAUD RATE:
	set /p baudrate=">"
	goto passthrough
)
if %errorlevel%==2 (
	echo.
	echo Enter Pipe Name:
	set /p PipeName="\\.\pipe\"
	goto passthrough
)
if %errorlevel%==3 (
	echo set cd=%cd% >"%temp%\PASCD.cmd
	echo set Port=!COMPort%SelectedPort%! >>"%temp%\PASCD.cmd
	echo set name=\\.\pipe\%PipeName% >>"%temp%\PASCD.cmd
	echo set baudrate=%baudrate% >>"%temp%\PASCD.cmd
	powershell start -verb runas 'Bin\Piper.bat'
	pause
	goto SelectedCOM
)
goto SelectedCOM

:DataPort
echo Enter data to enter to port
set /p comcommand="!COMPort%SelectedPort%!>"
echo %comcommand%>!COMPort%SelectedPort%!
timeout /t 1 /nobreak >nul
goto selectedcom

:typeport
start "" "Bin\ViewCOM.bat" !COMPort%SelectedPort%!
goto selectedcom

:comsetting
echo Enter setting type followed by and equal
echo sign and it's value for example: BAUD=1200
echo Available Settings are:
echo [BAUD=b] [PARITY=p] [DATA=d] [STOP=s]
echo [to=on|off] [xon=on|off] [odsr=on|off]
echo [octs=on|off] [dtr=on|off|hs]
echo [rts=on|off|hs|tg] [idsr=on|off]
echo Or enter X to cancel
set /p modecommand="!COMPort%SelectedPort%!>"
if /i "%modecommand%"=="X" goto SelectedCOM
mode %modecommand%
goto SelectedCOM



:ViewRadio
set Selected=1
set directory=Bin\Files\Radios
:SelectRadio
rem display a list of files in the Files\Vendors folder, allow the user to select one, and set the result to %vendor%
if "!Selected!"=="" set selected=1
set linecount=0
set item=0
set _skip=0
cls
call :titlebar
for /f "tokens=*" %%A in ('dir /b "!directory!"') do (
	set /a linecount+=1
	set /a item+=1
	set _echo=%%~nA
if exist "!directory!\%%~A\*" set _echo=}%%~A
	set /a _tmpVar=!selected!-!item!
	if !_tmpVar! LSS 35 (
		if "!Selected!"=="!item!" (
			echo !_echo! *
			set "_SelectedFile=%%~A"
			set "_SelectedExtension=%%~xA"
			set "_SelectedName=%%~nA"
		) ELSE (
			echo !_echo!
		)
	) ELSE (
		set /a _skip+=1
	)
	set /a _tmpVar=!linecount!-!_skip!
	if !_tmpVar!==%lines% (
		echo | set /p "= . . ."
		goto 1BreakLoop1
	)
)
:1BreakLoop1
"Bin\Kbd.exe"
if %errorlevel%==59 goto mainmenu
if %errorlevel%==60 goto Updates
if %errorlevel%==61 start "" "%~0"
if %errorlevel%==62 goto COMS
if %errorlevel%==68 exit /b
set _errorlevel=%errorlevel%
rem if %_errorlevel%==59 goto options
if %_errorlevel%==80 (
	if not !Selected! GEQ !linecount! (
		set /a Selected+=1
	)
)
if %_errorlevel%==72 (
	if not !Selected! LEQ 1 (
		set /a Selected-=1
	)
)
if %_errorlevel%==77 (
	if exist "%directory%\%_SelectedFile%\*" goto RadioEnterPressed
)
if %_errorlevel%==75 (
	if not "%directory%"=="Bin\Files\Radios" goto :SelectUpOne
)
if %_errorlevel%==8 (
	if not "%directory%"=="Bin\Files\Radios" goto :SelectUpOne
)

if %_errorlevel%==13 goto RadioEnterPressed
goto SelectRadio

:SelectUpOne
Rem Remove trailing backslash if present
if "!directory:~-1!"=="\" set "directory=!directory:~0,-1!"
Rem Find the position of the last backslash
set "lastpos=0"
for /l %%a in (0,1,1000) do (
    set /a "pos=lastpos+1"
    set "char=!directory:~%%a,1!"
    if "!char!"=="" set /a "lastpos-=1" & goto :S1break
    if "!char!"=="\" set "lastpos=%%a"
)
:S1break
Rem Extract the path up to the last backslash
set /a lastpos+=1
set "upOne=!directory:~0,%lastpos%!"
set directory=!upOne!
goto :SelectRadio

:RadioEnterPressed
if exist "%directory%\%_SelectedFile%\*" (
	set directory=%directory%\%_SelectedFile%
	set selected=1
	goto :SelectRadio
)
set Radio="%Directory%\%_SelectedFile%"
:LoadRadio
call %radio%
call :SetLC
call :setVC
Rem If path longer than 27 char, trim and append ...
set "len=0"
for /l %%A in (12,-1,0) do (
    set /a "len|=1<<%%A"
    for %%B in (!len!) do if "!SoftwarePath:~%%B,1!"=="" set /a "len&=~1<<%%A"
)
set /a "startPos=!len!-25"
if !len! gtr 27 (
    set "DisplayPath=...!SoftwarePath:~%startPos%,26!"
) else (
    set "DisplayPath=!SoftwarePath!"
)
:DisplayRadio
cls
call :Titlebar
echo %vendor% %model%    Press E to Edit 
echo -------------------------------------------------
echo Connector:          %jack%
echo TXD to Radio:-------Pin %TXD%
echo RXD From Radio:-----Pin %RXD%
if %RXD%==%TXD% echo                     HALF-DUPLEX
echo Ground Pin:---------Pin %GND%
echo Voltage:            %VC%%Voltage%
echo Compatible Cable:   %cable%
set mismatch=N
if exist "Bin\Files\Cables\Owned\%Cable%.cmd" (
	echo Owned?              Cable Owned
) ELSE (
	if exist "Bin\Files\Cables\%Cable%.cmd" (
		echo Owned?              Cable Not Owned
	) ELSE (
		echo Owned?              Cable Unknown
	)
	
)
echo -------------------------------------------------
echo Software:           %Software%
echo Software Path:      %DisplayPath%
if not "%SoftwarePath:"=%"=="None" (
	if exist "%SoftwarePath:"=%" (
		echo Installed:          Software Detected
		echo ---------^>          Press L to launch
	) ELSE (
		echo Installed:          Software Not Detected
	)
)
echo License Required:   %LC%%LicenseRequired%
echo -------------------------------------------------
echo Notes: %notes%
echo -------------------------------------------------
echo|set /p="Pins twins:  "
for /f "tokens=* delims=" %%A in ('dir /b "Bin\Files\UIDS\%uid%\*.uid1"') do (
	if not exist "Bin\Files\UID2S\%uid2%\%%~nA.uid2" (
		set TwinName=%%~nA
		echo|set /p="!TwinName:.= ! "
	)
)
echo.
echo|set /p="Full twins:  "
for /f "tokens=* delims=" %%A in ('dir /b "Bin\Files\UID2S\%uid2%\*.uid2"') do (
	if not "%%~nA"=="%vendor%.%model%" (
		set TwinName=%%~nA
		echo|set /p="!TwinName:.= ! "
	)
)
"Bin\kbd.exe"
if %errorlevel%==27 goto mainmenu
if %errorlevel%==59 goto mainmenu
if %errorlevel%==60 goto Updates
if %errorlevel%==61 start "" "%~0"
if %errorlevel%==62 goto COMS
if %errorlevel%==68 exit /b
if %errorlevel%==101 goto :PreConfigNewMenu
if %errorlevel%==108 (
	pushd "%userprofile%"
	start "" "%SoftwarePath%"
	popd
	goto :ReKBDNew
)
goto loadradio
goto DisplayRadio

:PreConfigNewMenu
Rem If path longer than 27 char, trim and append ...
set "len=0"
for /l %%A in (12,-1,0) do (
    set /a "len|=1<<%%A"
    for %%B in (!len!) do if "!SoftwarePath:~%%B,1!"=="" set /a "len&=~1<<%%A"
)
echo !len!
set /a "startPos=!len!-23"
if !len! gtr 27 (
    set "DisplayPath=...!SoftwarePath:~%startPos%,24!"
) else (
    set "DisplayPath=!SoftwarePath!"
)
goto confignewmenu



REM ==================================
REM START NEW RADIO SECTION
REM  =================================
:AddRadio
set Selected=1
:SelectVendor
rem display a list of files in the Files\Vendors folder, allow the user to select one, and set the result to %vendor%
if "!Selected!"=="" set selected=1
cls
call :titlebar
echo   Select Radio Vendor or Press N for new Vendor
echo =================================================
set linecount=0
set item=0
set _skip=0
for /f "tokens=*" %%A in ('dir /b Bin\Files\Vendors') do (
	set /a linecount+=1
	set /a item+=1
	set _echo=%%~A
if exist "%%~A\*.*" set _echo=}%%~A
	set /a _tmpVar=!selected!-!item!
	if !_tmpVar! LSS 35 (
		if "!Selected!"=="!item!" (
			echo !_echo! *
			set "_SelectedFile=%%~A"
			set "_SelectedExtension=%%~xA"
		) ELSE (
			echo !_echo!
		)
	) ELSE (
		set /a _skip+=1
	)
	set /a _tmpVar=!linecount!-!_skip!
	if !_tmpVar!==%lines% (
		echo | set /p "= . . ."
		goto 1BreakLoop1
	)
)
:1BreakLoop1
"Bin\Kbd.exe"
if %errorlevel%==110 goto newvendor
if %errorlevel%==59 goto mainmenu
if %errorlevel%==60 goto Updates
if %errorlevel%==61 start "" "%~0"
if %errorlevel%==62 goto COMS
if %errorlevel%==68 exit /b
set _errorlevel=%errorlevel%
rem if %_errorlevel%==59 goto options
if %_errorlevel%==80 (
	if not !Selected! GEQ !linecount! (
		set /a Selected+=1
	)
)
if %_errorlevel%==72 (
	if not !Selected! LEQ 1 (
		set /a Selected-=1
	)
)
if %_errorlevel%==13 goto SelectedVendor
goto selectvendor

:newvendor
echo Enter vendor name:
echo X to cancel
set /p Vendor=">"
if /i "%vendor%"=="X" goto :SelectVendor
echo.>"Bin\Files\Vendors\%Vendor:"=%"
goto NewModel

:SelectedVendor
set Vendor=%_SelectedFile:"=%
:NewModel
cls
echo Vendor: %Vendor%
echo ===========================
echo Enter new Model Number
set /p Model=">"
if exist "Bin\Files\Radios\%vendor%\%model%.cmd" (
	echo This model already exists.
	pause
	goto mainmenu
)
set VendorURL=!vendor: =%%20!
set ModelURL=!Model: =%%20!
curl -s -H "Accept: application/vnd.github.v3.raw" -L https://api.github.com/repos/W1BTR/Programming-Assistant/contents/Bin/Files/Radios/!VendorURL!/!ModelURL!.cmd -o ModelCheck.Temp.cmd
find "https://docs.github.com/rest/repos/contents#get-repository-content" "ModelCheck.Temp.cmd" >nul 2>nul
if %errorlevel%==1 (
	call ModelCheck.Temp.cmd
	echo A matching model name was found in the online
	echo repository with the following details:
	echo Vendor:      !vendor!
	echo Model:       !model!
	echo Jack:        !jack!
	echo TXD:         !txd!
	echo RXD:         !rxd!
	echo GND:         !gnd!
	echo Voltage:     !voltage!
	echo Software:    !software!
	echo Cable:       !cable!
	echo Notes:       !notes!
	echo Download Model?
	choice
	if %errorlevel%==2 (
		del /f /q ModelCheck.Temp.cmd
		goto CONFIGNEW
	)
	copy "ModelCheck.Temp.cmd" "Bin\Files\Radios\%vendor%\%model%.cmd"
	del /f /q ModelCheck.Temp.cmd

)
goto CONFIGNEW

:CONFIGNEW
rem set some default variables
set jack=RJ45
set voltage=5V
set TXD=
set RXD=
set GND=
set Cable=
set Software=
set Notes=
set VoltageUnset=true
set LicenseRequired=Yes
set SoftwarePath=None
set selected=1
call :SetLC
call :SetVC
:Confignewmenu
call :setcursor
cls
call :titlebar
echo Editing: %Vendor% %Model%
echo == Communication ================================
echo %cur_1%1 Jack:               %jack% 
echo %cur_2%2 TXD (PC to Radio):  %TXD%
echo %cur_3%3 RXD (Radio to PC):  %RXD%
echo %cur_4%4 GND:                %GND%
echo %cur_5%5 Voltage:            %VC%%VOLTAGE%
echo %cur_6%6 Cable Name:         %cable%
set mismatch=N
if exist "Bin\Files\Cables\%Cable%.cmd" (
	call "Bin\Files\Cables\%Cable%.cmd"
	if not "%TXD%"=="!CableTXD!" set mismatch=Y
	if not "%RXD%"=="!CableRXD!" set mismatch=Y
	if not "%GND%"=="!CableGND!" set mismatch=Y
	if not "%Voltage%"=="!CableV!" set mismatch=Y
	if "!mismatch!"=="Y" (
		echo C Owned?              Cable mismatch PRESS C
	) ELSE (
		if exist "Bin\Files\Cables\Owned\%Cable%.cmd" (
			echo C Owned?              Cable Owned
		) ELSE (
			echo C Cable Unowned Press C to mark as owned
		)
	)
) ELSE (
	echo C Cable Unknown Press C to add to library
)
echo == Software =====================================
echo %cur_7%7 Software:           %Software%
echo %cur_8%8 License Required:   %LC%%LicenseRequired%
echo %cur_9%9 Software Path:      %DisplayPath%
if not "%SoftwarePath:"=%"=="None" (
	if exist "%SoftwarePath:"=%" (
		echo L Detected?       Software Detected
	) ELSE (
		echo L Detected?       Software Not Detected
	)
) ELSE (
	echo Enter software path to detect install
)
echo == Notes ========================================
echo %cur_0%0 Notes: %notes%
echo -------------------------------------------------
echo Press S to save
echo Press I to import from twin radio
echo Press X to close
if not "%SoftwarePath:"=%"=="None" (
	if exist "%SoftwarePath:"=%" echo Press L to Launch %Software%
)
echo -------------------------------------------------
REM TODO
rem navigate creation
rem create uniqueID to find programming cable twins
rem save to file
rem twin importing
:ReKBDNew
"Bin\Kbd.exe"
if %errorlevel%==80 (
	if not !Selected! GEQ 10 (
		set /a Selected+=1
	)
)
if %errorlevel%==72 (
	if not !Selected! LEQ 1 (
		set /a Selected-=1
	)
)
if %errorlevel%==108 (
	pushd "%userprofile%"
	start "" "%SoftwarePath%"
	popd
	goto :ReKBDNew
)
cls
if %errorlevel%==49 (
	call :SetJack
	goto :Confignewmenu
)
if %errorlevel%==50 (
	call :SetTXD
	goto :Confignewmenu
)
if %errorlevel%==51 (
	call :SetRXD
	goto :Confignewmenu
)
if %errorlevel%==52 (
	call :SetGND
	goto :Confignewmenu
)
if %errorlevel%==53 (
	call :SetVLT
	call :SetVC
	goto :Confignewmenu
)
if %errorlevel%==54 (
	call :SetCable
	goto :Confignewmenu
)
if %errorlevel%==55 (
	call :SetSoftware
	goto :Confignewmenu
)
if %errorlevel%==56 (
	call :SetLicense
	call :SetLC
	goto :Confignewmenu
)
if %errorlevel%==57 (
	call :SetSPath
	goto :Confignewmenu
)

if %errorlevel%==48 (
	call :SetNote
	goto :Confignewmenu
)

if %errorlevel%==59 goto mainmenu
if %errorlevel%==60 goto Updates
if %errorlevel%==61 start "" "%~0"
if %errorlevel%==62 goto COMS
if %errorlevel%==68 exit /b

if %errorlevel%==105 goto importRadio
if %errorlevel%==13 goto SelNewMenu
if %errorlevel%==115 goto SaveRadio
if %errorlevel%==120 goto mainmenu
if %errorlevel%==99 (
	call :SaveCable
	goto :Confignewmenu
)
goto Confignewmenu

:importRadio


:SaveCable
if %mismatch%==N (
	if exist "Bin\Files\Cables\%cable%.cmd" (
		echo Cable exists but is marked as unowned.
		goto DoYouOwn
	) ELSE (
		echo Adding new cable to library
	)
) ELSE (
	echo Cable Mismatch
)
if not exist "Bin\Files\Cables\Owned\" md "Bin\Files\Cables\Owned\"
if %mismatch%==Y call :updatecable
if %mismatch%==Y exit /b
echo Ensure the pins are set up properly
echo before saving the cable.
echo.
echo TXD to Radio: %TXD%
echo RXD from Radio: %RXD%
echo GND for both: %GND%
echo Data Voltage: %voltage%
echo.
echo Save?
choice
if %errorlevel%==2 exit /b
(echo @echo off)>"Bin\Files\Cables\%Cable%.cmd"
(Echo set CableTXD=%TXD%)>>"Bin\Files\Cables\%Cable%.cmd"
(Echo set CableRXD=%RXD%)>>"Bin\Files\Cables\%Cable%.cmd"
(Echo set CableGND=%GND%)>>"Bin\Files\Cables\%Cable%.cmd"
(Echo set CableV=%voltage%)>>"Bin\Files\Cables\%Cable%.cmd"
echo Cable Saved.
:DoYouOwn
echo Do you own this cable?
choice
if %errorlevel%==1 (
	(Echo.)>>"Bin\Files\Cables\Owned\%Cable%.cmd"
	echo Cable added to owned Library.
) ELSE (
	if exist "Bin\Files\Cables\Owned\%Cable%.cmd" (
		del /f /q "Bin\Files\Cables\Owned\%Cable%.cmd"
		echo Cable removed from owned Library.
	)
)

pause
exit /b

:updatecable
rem color code
if not "%TXD%"=="%CableTXD%" (
	set pTXD=
) ELSE (
	set pTXD=
)
if not "%RXD%"=="%CableRXD%" (
	set pRXD=
) ELSE (
	set pRXD=
)
if not "%GND%"=="%CableGND%" (
	set pGND=
) ELSE (
	set pGND=
)
if not "%voltage%"=="%CableV%" (
	set pV=
) ELSE (
	set pV=
)
echo The current Pin Layout does not
echo match the pins saved for %cable%.
echo Current Settings:
echo TXD to Radio: !pTXD!%TXD%
echo RXD from Radio: !pRXD!%RXD%
echo GND for both: !pGND!%GND%
echo Data Voltage: !pV!%voltage%
echo %cable% Saved Pins:
echo TXD to Radio: !pTXD!%CableTXD%
echo RXD from Radio: !pRXD!%CableRXD%
echo GND for both: !pGND!%CableGND%
echo Data Voltage: !pV!%CableV%
echo.
echo 1] Overwrite saved cable
echo 2] Pull from saved cable
echo 3] Change cable name
echo X] Go back
choice /c 1234x
if %errorlevel%==1 (
	(echo @echo off)>"Bin\Files\Cables\%Cable%.cmd"
	(Echo set CableTXD=%TXD%)>>"Bin\Files\Cables\%Cable%.cmd"
	(Echo set CableRXD=%RXD%)>>"Bin\Files\Cables\%Cable%.cmd"
	(Echo set CableGND=%GND%)>>"Bin\Files\Cables\%Cable%.cmd"
	(Echo set CableV=%voltage%)>>"Bin\Files\Cables\%Cable%.cmd"
	echo Cable Saved.
	pause
	exit /b
)
if %errorlevel%==2 (
	set TXD=%CableTXD%
	set RXD=%CAbleRXD%
	set GND=%CableGND%
	set Voltage=%CableV%
	echo Pulled Settings.
	pause
	exit /b
)
if %errorlevel%==3 (
	call :SetCable
	exit /b
)
exit /b

:SetVC
set VC=
rem set color of voltage text depending on value, and append V if needed
if "!Voltage!"=="5V" set VC=
if "!Voltage!"=="3.3V" set VC=
if "!Voltage!"=="1.8V" set VC=
if "!Voltage!"=="5" set VC=& set Voltage=5V
if "!Voltage!"=="3.3" set VC=& set Voltage=3.3V
if "!Voltage!"=="1.8" set VC=& set Voltage=1.8V
exit /b

:SetLC
rem set color of License Required text
if "!LicenseRequired!"=="Yes" set LC=
if "!LicenseRequired!"=="No" set LC=
exit /b

:SetCable
echo Enter name of a cable (i.e. Kenwood KPG-46X):
set /p cable=">"
if exist "Bin\Files\Cables\%Cable%.cmd" (
	call "Bin\Files\Cables\%Cable%.cmd"
	if "%TXD%"=="" set TXD=!CableTXD!
	if "%RXD%"=="" set RXD=!CableRXD!
	if "%GND%"=="" set GND=!CAbleGND!
	if "%VoltageUnset%"=="True" set voltage=!CableV!
)
exit /b

:SetNote
echo Enter a new note:
set /p notes=">"
exit /b

:SelNewMenu
rem enter was pressed, figure out which menu to go to
if %selected%==1 (
	call :SetJack
	goto :Confignewmenu
)
if %selected%==2 (
	call :SetTXD
	goto :Confignewmenu
)
if %selected%==3 (
	call :SetRXD
	goto :Confignewmenu
)
if %selected%==4 (
	call :SetGND
	goto :Confignewmenu
)
if %selected%==5 (
	call :SetVLT
	call :SetVC
	goto :Confignewmenu
)
if %selected%==6 (
	call :SetCable
	goto :Confignewmenu
)
if %selected%==7 (
	call :SetSoftware
	goto :Confignewmenu
)
if %selected%==8 (
	call :SetLicense
	call :SetLC
	goto :Confignewmenu
)
if %selected%==9 (
	call :SetSPath
	goto :Confignewmenu
)
if %selected%==10 (
	call :SetNote
	goto :Confignewmenu
)
goto Confignewmenu

:SetLicense
echo Is a license required to use the
echo %software% software?
choice
if %errorlevel%==1 set LicenseRequired=Yes
if %errorlevel%==2 set LicenseRequired=No
if exist "Bin\Files\Software\!software!.cmd" call "Bin\Files\Software\!software!.cmd"
if exist "Bin\Files\Software\!software!.cmd" (
	if not "!SoftwareLicenseRequired!"=="!LicenseRequired!" (
		echo Save change for %software%?
		choice
		if !errorlevel!==1 (
			echo @echo off >"Bin\Files\Software\!software!.cmd"
			echo set DefaultPath=!DefaultPath!>>"Bin\Files\Software\!software!.cmd"
			echo Set SoftwareLicenseRequired=!LicenseRequired!>>"Bin\Files\Software\!software!.cmd"
		)
	)
) ELSE (
	echo Additionally save License required as %LicenseRequired%
	echo for %Software%?
	choice
	if !errorlevel!==1 (
		echo @echo off >"Bin\Files\Software\!software!.cmd"
		echo set DefaultPath=!DefaultPath!>>"Bin\Files\Software\!software!.cmd"
		echo Set SoftwareLicenseRequired=!LicenseRequired!>>"Bin\Files\Software\!software!.cmd"
	)
)
exit /b

:SetSPath
echo Select the executable file to run the
echo programming software for the %vendor% %model%
set OpenPath=C:\
if not "%SoftwarePath%"=="" for %%i in ("%SoftwarePath%") do set "OpenPath=%%~dpi\"
for /f "tokens=*" %%A in ('call bin\chooser.bat "%OpenPath%"') do (
	set SoftwarePath=%%~A
	set SoftwareTemp=%%~nA
)
if "%softwarePath%"=="" (
	set SoftwarePath=None
	Set DisplayPath=
	exit /b
)
if "%software%"=="" set Software=!SoftwareTemp!
rem check if a file on this software already exists. If it does, check if it's different
if exist "Bin\Files\Software\!software!.cmd" call "Bin\Files\Software\!software!.cmd"
if exist "Bin\Files\Software\!software!.cmd" (
	if not "!DefaultPath:^)=^)!"=="!SoftwarePath:^)=^)!" (
		echo Overwrite !DefaultPath! with
		echo !SoftwarePath! for %Software%?
		choice
		if !errorlevel!==1 (
			echo @echo off >"Bin\Files\Software\!software!.cmd"
			echo set DefaultPath=!SoftwarePath:^)=^)!>>"Bin\Files\Software\!software!.cmd"
			echo Set SoftwareLicenseRequired=!SoftwareLicenseRequired!>>"Bin\Files\Software\!software!.cmd"
		)
	)
) ELSE (
	echo Additionally save: 
	echo !SoftwarePath:^)=^)!
	echo as the default path for %software%?
	choice
	if !errorlevel!==1 (
		echo @echo off >"Bin\Files\Software\!software!.cmd"
		echo set DefaultPath=!SoftwarePath:^)=^)!>>"Bin\Files\Software\!software!.cmd"
		echo Set SoftwareLicenseRequired=!LicenseRequired!>>"Bin\Files\Software\!software!.cmd"
	)
)
Rem If path longer than 27 char, trim and append ...
set "len=0"
for /l %%A in (12,-1,0) do (
    set /a "len|=1<<%%A"
    for %%B in (!len!) do if "!SoftwarePath:~%%B,1!"=="" set /a "len&=~1<<%%A"
)
echo !len!
set /a "startPos=!len!-23"
if !len! gtr 27 (
    set "DisplayPath=...!SoftwarePath:~%startPos%,24!"
) else (
    set "DisplayPath=!SoftwarePath!"
)
exit /b

:SetSoftware
echo Enter the name of the %vendor% or third party
echo software used to program the %model%.
set /p software=">"
if not exist "Bin\Files\Software\!software!.cmd" exit /b
call "Bin\Files\Software\!software!.cmd"
set LicenseRequired=!SoftwareLicenseRequired!
if exist "!DefaultPath!" set SoftwarePath=!DefaultPath!
Rem If path longer than 27 char, trim and append ...
set "len=0"
for /l %%A in (12,-1,0) do (
    set /a "len|=1<<%%A"
    for %%B in (!len!) do if "!SoftwarePath:~%%B,1!"=="" set /a "len&=~1<<%%A"
)
echo !len!
set /a "startPos=!len!-23"
if !len! gtr 27 (
    set "DisplayPath=...!SoftwarePath:~%startPos%,24!"
) else (
    set "DisplayPath=!SoftwarePath!"
)
exit /b

:SetVLT
echo Enter the voltage expected by the radio for serial communication.
echo This will usually be 5V, but may be 3.3, or 1.8v.
set /p voltage=">"
set VoltageUnset=false
exit /b

:SetGND
	echo Enter the pin on the %jack% connector for GROUND.
	set /p GND=">"
exit /b

:SetTXD
	echo Enter the Pin on the %jack% connector for
	echo data going to the radio from the computer.
	echo.
	echo On the radio, this will likely be labeled RXD.
	echo On the cable, it will likely be labeled TXD.
	set /p TXD=">"
exit /b

:SetRXD
	echo Enter the Pin on the %jack% connector for
	echo data going to the computer from the radio.
	echo.
	echo On the radio, this will likely be labeled TXD.
	echo On the cable, it will likely be labeled RXD.
	set /p RXD=">"
exit /b

:SetJack
	echo Suggested Jacks:
	echo RJ45, RJ11
	echo DB9, DB15, DB9, DB25, DB37
	echo 3.5mm TRS, 3.5mm TRRS, 2.5mm TRS, 2.5mm TRRS
	echo.
	set /p jack=">"
	set istrs=yes
	set istrrs=yes
	if "!jack!"=="!jack:TRS=!" (
		if "!jack!"=="!jack:trs=!" (
			set istrs=no
		)
	)
	if "!jack!"=="!jack:TRRS=!" (
		if "!jack!"=="!jack:trrs=!" (
			set istrrs=no
		)
	)
	if "!istrs!"=="yes" (
		if not "%dontdisplaytrs%"=="TRUE" (
			echo LOADING GUIDE...
			cls
			type Bin\TRS.ascii
			echo.
			pause
		)
	)
	if "!istrrs!"=="yes" (
		if not "%dontdisplaytrs%"=="TRUE" (
			echo LOADING GUIDE...
			cls
			type Bin\TRRS.ascii
			echo.
			pause
		)
	)
exit /b



:setcursor
rem callable section to add a color inverting character to a variable if the selected line matches
if %selected%==1 (
	set cur_1=
) ELSE (
	set cur_1=
)
if %selected%==2 (
	set cur_2=
) ELSE (
	set cur_2=
)
if %selected%==3 (
	set cur_3=
) ELSE (
	set cur_3=
)
if %selected%==4 (
	set cur_4=
) ELSE (
	set cur_4=
)
if %selected%==5 (
	set cur_5=
) ELSE (
	set cur_5=
)
if %selected%==6 (
	set cur_6=
) ELSE (
	set cur_6=
)
if %selected%==7 (
	set cur_7=
) ELSE (
	set cur_7=
)
if %selected%==8 (
	set cur_8=
) ELSE (
	set cur_8=
)
if %selected%==9 (
	set cur_9=
) ELSE (
	set cur_9=
)
if %selected%==10 (
	set cur_0=
) ELSE (
	set cur_0=
)
exit /b
REM ==========================================
REM END ADD RADIO CONFIG
REM ==========================================


:SaveRadio
cls
echo Saving %vendor% %model% . . .
if not exist "Bin\Files\Radios\%vendor%\" md "Bin\Files\Radios\%vendor%\"
if exist "Bin\Files\Radios\%vendor%\%model%.cmd" (
	echo There is already a save file for:
	echo %vendor% %model%.
	echo Overwrite?
	choice
	if %errorlevel%==2 goto mainmenu
)
rem set unique identifiers of programing cable and software
echo Generating Radio File . . .
set uid=%jack%%txd%%rxd%%gnd%%voltage%
set uid2=%jack%%txd%%rxd%%gnd%%voltage%%software%
rem create a callable file with all the variables
echo @echo off >"Bin\Files\Radios\%vendor%\%model%.cmd"
echo rem Last modified %date% %time% >>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set vendor=%vendor%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set model=%model%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set jack=%jack%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set txd=%txd%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set rxd=%rxd%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set gnd=%gnd%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set voltage=%voltage%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set software=%software%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
echo set softwarepath=%softwarepath%>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set licenserequired=%licenserequired%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set cable=%cable%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set notes=%notes%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set uid=%uid%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
(echo set uid2=%uid2%)>>"Bin\Files\Radios\%vendor%\%model%.cmd"
rem save UID and UID2 for looking up compatible radios. If a UID DB doesnt exist matching the uid, creatge one.
echo Generating UID Files . . .
for /f "tokens=* delims=*" %%A in ('dir /b /s "%vendor%.%model%.uid1"') do (if exist "%%~A" del /f /q "%%~A")
for /f "tokens=* delims=*" %%A in ('dir /b /s "%vendor%.%model%.uid2"') do (if exist "%%~A" del /f /q "%%~A")
if not exist "Bin\Files\UIDS\%uid%\" md "Bin\Files\UIDS\%uid%\"
if not exist "Bin\Files\UID2S\%uid2%\" md "Bin\Files\UID2S\%uid2%\"
echo Saving UID Files . . .
echo [%vendor%\%model%]>"Bin\Files\UIDS\%uid%\%vendor%.%model%.uid1"
echo [%vendor%\%model%]>"Bin\Files\UID2S\%uid2%\%vendor%.%model%.uid2"
echo.
echo Done.
pause
set radio="Bin\Files\Radios\%vendor%\%model%.cmd"
goto loadradio








:menunavscript
echo Navigate
for /f "tokens=*" %%A in ('dir /b Bin\Files\Vendors') do (
	set /a linecount+=1
	set /a item+=1
	set _echo=%%~A
if exist "%%~A\*.*" set _echo=}%%~A
	set /a _tmpVar=!selected!-!item!
	if !_tmpVar! LSS 35 (
		if "!Selected!"=="!item!" (
			echo !_echo! *
			set "_SelectedFile=%%~A"
			set "_SelectedExtension=%%~xA"
		) ELSE (
			echo !_echo!
		)
	) ELSE (
		set /a _skip+=1
	)
	set /a _tmpVar=!linecount!-!_skip!
	if !_tmpVar!==%lines% (
		echo | set /p "= . . ."
		goto 1BreakLoop1
	)
)
:1BreakLoop1
"Bin\Kbd.exe"
set _errorlevel=%errorlevel%
rem if %_errorlevel%==59 goto options
if %_errorlevel%==80 set /a Selected+=1
if %_errorlevel%==72 set /a Selected-=1
if %_errorlevel%==13 goto SelectVendor