build.gradle

plugins {
    id "base"
    id "signing"
    alias libs.plugins.nexus.publish
    id "dex2jar.build-conventions"
    alias libs.plugins.versions
}

description = 'Supermodule for dex2jar'

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
            var ossrhUsername = providers.environmentVariable("OSSRH_USERNAME")
            var ossrhPassword = providers.environmentVariable("OSSRH_PASSWORD")
            if (ossrhUsername.present && ossrhPassword.present) {
                username.set(ossrhUsername.get())
                password.set(ossrhPassword.get())
            }
        }
    }
}

dependencies {
    api(project(":d2j-base-cmd"))
    api project(path: ':d2j-external', configuration: 'shadow')
    api(project(":d2j-jasmin"))
    api(project(":d2j-smali"))
    api(project(":dex-ir"))
    api(project(":dex-reader"))
    api(project(":dex-reader-api"))
    api(project(":dex-tools"))
    api(project(":dex-translator"))
    api(project(":dex-writer"))
}