build.gradle

buildscript {
    /*ext {
        kotlin_version = '1.5.21'
    }*/
    repositories {
        google()
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:7.0.2'
        classpath 'com.google.gms:google-services:4.3.10'
        classpath 'com.google.firebase:firebase-crashlytics-gradle:2.7.1'
        //classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

allprojects {
    repositories {
        maven { url 'https://jitpack.io' }
        google()
        mavenCentral()
    }
}

def getReleaseVersionCode() {
    def versionCode = (int) (new Date().getTime() / 1000)
    println('versionCode: ' + versionCode)
    return versionCode
}

def getReleaseVersionName() {
    def baseline = '1.7.0'
    def versionName = baseline + '.' + new Date().format('yyMMdd')
    println('versionName: ' + versionName)
    return versionName
}

def localProperties = new Properties()
def localPropertiesFile = new File(rootDir.getAbsolutePath(), 'local.properties')
if (localPropertiesFile.exists()) {
    localProperties.load(localPropertiesFile.newDataInputStream())
}

apply plugin: 'com.android.application'
apply plugin: 'com.google.gms.google-services'
apply plugin: 'com.google.firebase.crashlytics'

//apply plugin: 'kotlin-android'
//apply plugin: 'kotlin-android-extensions'

android {
    compileSdkVersion 31
    ndkVersion '22.1.7171670'

    defaultConfig {
        minSdkVersion 24
        targetSdkVersion 29
        versionCode getReleaseVersionCode()
        versionName getReleaseVersionName()
        ndk {
            abiFilters 'x86', 'x86_64', 'armeabi-v7a', 'arm64-v8a'
        }
    }

    packagingOptions {
        exclude 'META-INF/proguard/coroutines.pro'
    }

    signingConfigs {
        debug {
            storeFile file('debug.jks')
            storePassword "debug.dgsrz.com"
            keyAlias 'debug.github.dgsrz.com'
            keyPassword 'debug.github.dgsrz.com'
        }

        release {
            try {
                storeFile file(localProperties.get("RELEASE_KEYSTORE", "debug.jks"))
                storePassword localProperties.get('RELEASE_KEYSTORE_PASSWORD', "debug.dgsrz.com")
                keyAlias localProperties.get('RELEASE_KEY_ALIAS', "debug.github.dgsrz.com")
                keyPassword localProperties.get('RELEASE_KEY_PASSWORD', "debug.github.dgsrz.com")
            } catch (ignored) {
                throw new InvalidUserDataException('You should define RELEASE_KEYSTORE_PASSWORD and RELEASE_KEY_PASSWORD in local.properties.', ignored)
            }
        }
    }

    buildTypes {
        debug {
            resValue "string", "app_name", "rimu!-debug"
            applicationIdSuffix '.debug'
            firebaseCrashlytics {
                mappingFileUploadEnabled false
            }
        }

        release {
            resValue "string", "app_name", "rimu!"
            zipAlignEnabled true
//            minifyEnabled true
//            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard.cfg', 'proguard-kotlin.pro'
            signingConfig signingConfigs.release
            firebaseCrashlytics {
                mappingFileUploadEnabled false
            }
        }

        pre_release {
            matchingFallbacks = ['release']
            resValue "string", "app_name", "rimu!"
            zipAlignEnabled true
//            minifyEnabled true
//            debuggable true
//            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard.cfg', 'proguard-kotlin.pro'
            signingConfig signingConfigs.release
            firebaseCrashlytics {
                mappingFileUploadEnabled false
            }
        }
    }

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
            jniLibs.srcDirs = ['libs']
        }
        androidTest.setRoot('tests')
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    useLibrary 'org.apache.http.legacy'

    lintOptions {
        abortOnError true
        ignoreWarnings true
        disable 'MissingTranslation', 'ExpiredTargetSdkVersion', 'ProtectedPermissions', 'AppLinkUrlError'
    }

    android.applicationVariants.all { variant ->
        variant.outputs.all { output ->
            def fileName = "rimu!-${defaultConfig.versionName}-${variant.buildType.name}.apk"
            outputFileName = fileName
        }
    }
}

dependencies {
    implementation project(':AndEngine')
    implementation project(':andnext_markdown')

    implementation 'androidx.legacy:legacy-support-v4:1.0.0'
    implementation 'androidx.preference:preference:1.1.1'
    implementation 'androidx.palette:palette:1.0.0'

    implementation 'com.google.firebase:firebase-crashlytics:18.2.1'
    implementation 'com.google.firebase:firebase-analytics:19.0.1'
    implementation 'com.google.firebase:firebase-messaging:22.0.0'
    implementation 'com.google.android.material:material:1.6.1'
    implementation 'com.google.code.gson:gson:2.8.8'

    implementation 'com.squareup.okhttp3:okhttp:4.9.0'
    implementation 'pub.devrel:easypermissions:3.0.0'
    implementation 'net.lingala.zip4j:zip4j:2.9.0'

    implementation 'com.github.EdrowsLuo:osudroidstrings:bd9507b289'
    implementation 'com.github.EdrowsLuo.EdlGameFramework:EdlJavaExt:d91c53fcff'
    implementation 'com.github.EdrowsLuo.EdlGameFramework:EdlOsbSupport:d91c53fcff'
    implementation project(path: ':LibBASS')
    //implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"

    implementation 'com.intuit.sdp:sdp-android:1.1.0'
    implementation 'com.intuit.ssp:ssp-android:1.1.0'
    implementation 'com.github.valkriaine:Bouncy:2.3'
}