Test the top X packages w/ sbom-tool support

[JonDouglas]

We should test the top X packages to see how well the sbom-tool performs when functionality is available in the .NET SDK for .NET 9.

Query

Top 1000 packages, taking at most 3 packages per unique set of owners (Microsoft packages don't overwhelm the list).

let IdDownloads = NiPackageDownloads | distinct LowerId, TotalDownloads;
let OwnerDownloads = NiPackageOwners
| join kind=inner IdDownloads on LowerId
| extend Owners = tostring(Owners)
| summarize OwnerDownloads = sum(TotalDownloads) by Owners;
NiPackageOwners
| extend Owners = tostring(Owners)
| join kind=inner OwnerDownloads on Owners
| project-away Owners1
| join kind=inner IdDownloads on LowerId
| project-away LowerId1
| order by OwnerDownloads desc, Owners desc, TotalDownloads desc
| where row_number(1, Owners != prev(Owners)) <= 3
| join kind=inner (NiPackageVersions | where IsLatestSemVer2 | project Identity, LowerId, Id, Version, Created) on LowerId
| extend NupkgUrl = strcat("https://api.nuget.org/v3-flatcontainer/", Identity, "/", LowerId, ".", tolower(Version), ".nupkg")
| project Id, Version, Created, TotalDownloads, NupkgUrl
| order by TotalDownloads desc
| take 1000

[dotnet-policy-service]

@JonDouglas Issue is missing Type label, remember to add a Type label