Module system types.attrTag shadows name argument for inner submodules

[8aed]

Describe the bug

If I have an option with type attrsOf (attrTag { ... }), and use a submodule for the types of the tag, this submodule receives the tag name in name, rather than the parent attribute's name.

I understand this may be expected given how submodulesWith is defined (it has no way to know that last loc is a tag name), however, unless I've missed something obvious, it means that submodules can not get access to the parent attribute's name when used in a tag type.

I've tried to fix this myself but it kept breaking other things, and I haven't yet found a way to overcome this limitation/bug.

Steps To Reproduce

# test.nix
let pkgs = import ./nix {}; lib = pkgs.lib;
in with lib; with lib.types; let
  result = evalModules {
    modules = [
      ({ lib, ... }: let 
        mySubmodule = lib.types.submodule (
          { name, ... }: {
            options.myName = lib.mkOption {
              default = name;
              type = lib.types.str;
            };
          }
        );
      in {
        options.tagged = lib.mkOption {
          default = { foo.myTag = {}; bar.myTag = {}; };
          type = attrsOf (lib.types.attrTag {
            myTag = lib.mkOption {
              description = " a tag";
              type = mySubmodule;
            };
          });
        };

        options.notTagged = lib.mkOption {
          type = attrsOf (mySubmodule);
          default = { foo = {}; bar = {}; };
        };
      })
    ];
  };
in result.config

[nix-shell:/tmp/ghjk5]$ nix-instantiate --eval test.nix --strict --json
{"notTagged": {"bar":{"myName":"bar"},"foo":{"myName":"foo"}},
  "tagged":{"bar":{"myTag":{"myName":"myTag"}},"foo":{"myTag":{"myName":"myTag"}}}}

Expected behavior

[nix-shell:/tmp/ghjk5]$ nix-instantiate --eval test.nix --strict --json
{"notTagged": {"bar":{"myName":"bar"},"foo":{"myName":"foo"}},
  "tagged":{"bar":{"myTag":{"myName":"bar"}},"foo":{"myTag":{"myName":"foo"}}}}

Notify maintainers

@roberth
@infinisil

Metadata

Tested on nixos-unstable with Nix 2.18

[8aed]

One thing I tried that can fix this is making submoduleWith receive an index to read loc (in merge), rather than just taking last loc, and specializing submodule in taggedSubmodule to make it skip the tag name. There is also the possibility of specializing attrTag (attrTagWithSubmodules).

If one of these solutions is acceptable, I'd be happy to send a PR, but wanted to discuss it here first.

[infinisil]

Thanks for the report! I think the best way to resolve that would go in the direction of #97378 (comment), see also #344216

[roberth]

last loc was always a bit of a hack imo.

#344216

Specifically this, I would think:

itemTypeFunction = name: submoduleWith { modules = f name; specialArgs = g name; };

So you'd be able to write

type = attrsWith {
  itemTypeFunction = name:
    attrTag {
      foo = mkOption {
        type = submoduleWith {
          # This seems like a good idea, but not strictly necessary as long as all usages or in `modules` below...
          specialArgs.name = name;
          modules = [
            { # ... because you could just use name directly here
              options.myName = mkOption { default = name; };
            }
          ];
        };
      };
    };
};

I think this is a good strategy. It just depends on having an attrsWith function to extend. Unfortunately the first commit of #344216 does too much. Otherwise, I'd merge that commit right away.