From 89cd7ea2367d9b17551ca23a84ce95a9743731ed Mon Sep 17 00:00:00 2001
From: Bart Brouns <bart@magnetophon.nl>
Date: Thu, 28 May 2020 00:10:52 +0200
Subject: [PATCH] airwindows: init at 2020-05-25

---
 .../applications/audio/airwindows/default.nix | 62 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 64 insertions(+)
 create mode 100644 pkgs/applications/audio/airwindows/default.nix

diff --git a/pkgs/applications/audio/airwindows/default.nix b/pkgs/applications/audio/airwindows/default.nix
new file mode 100644
index 0000000000000..cba58032c892c
--- /dev/null
+++ b/pkgs/applications/audio/airwindows/default.nix
@@ -0,0 +1,62 @@
+{ stdenv, fetchFromGitHub, requireFile, unzip, cmake }:
+
+stdenv.mkDerivation rec {
+  name = "airwindows-${version}";
+  version = "2020-05-25";
+
+  src = fetchFromGitHub {
+    owner = "airwindows";
+    repo = "airwindows";
+    rev = "897c0830e603a950e838a3753f89334bdf56bb71";
+    sha256 = "1mh7c176fdl5y5ixkgzj2j2b7qifp3lgnxmbn6b7bvg3sv5wsxg3";
+  };
+
+  vst-sdk = stdenv.mkDerivation rec {
+    name = "vstsdk366_27_06_2016_build_61";
+    src = requireFile {
+      name = "${name}.zip";
+      url = "https://www.steinberg.net/sdk_downloads/vstsdk366_27_06_2016_build_61.zip";
+      sha256 = "05gsr13bpi2hhp34rvhllsvmn44rqvmjdpg9fsgfzgylfkz0kiki";
+    };
+    nativeBuildInputs = [ unzip ];
+    installPhase = "cp -r . $out";
+  };
+
+  airwindows-ports = stdenv.mkDerivation rec {
+    name = "airwindows-ports";
+    src = fetchFromGitHub {
+      owner = "ech2";
+      repo = "airwindows-ports";
+      rev = "0.4.0";
+      sha256 = "1ya4qbc63sb52nzisdapsydrnnpqnjsl5kgxibbr3dxf32474g89";
+    };
+    installPhase = "cp -r . $out";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  patchPhase = ''
+    cd plugins/LinuxVST
+    rm build/CMakeCache.txt
+    mkdir -p include/vstsdk
+    cp -r ${airwindows-ports}/include/vstsdk/CMakeLists.txt include/vstsdk/
+    cp -r ${vst-sdk}/pluginterfaces include/vstsdk/pluginterfaces
+    cp -r ${vst-sdk}/public.sdk/source/vst2.x/* include/vstsdk/
+    chmod -R 777 include/vstsdk/pluginterfaces
+  '';
+
+  installPhase = ''
+    for so_file in *.so; do
+      install -vDm 644 $so_file -t "$out/lib/lxvst"
+    done;
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Handsewn bespoke linuxvst plugins";
+    homepage = http://www.airwindows.com/airwindows-linux/;
+    # airwindows is mit, but the vst sdk is unfree
+    license = licenses.unfree;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.magnetophon ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index b92c8e91b5b60..0f6442af170de 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -18580,6 +18580,8 @@ in
 
   airwave = callPackage ../applications/audio/airwave { };
 
+  airwindows = callPackage ../applications/audio/airwindows { };
+
   akira-unstable = callPackage ../applications/graphics/akira { };
 
   alembic = callPackage ../development/libraries/alembic {};