-
Notifications
You must be signed in to change notification settings - Fork 32
/
confex.ex
331 lines (264 loc) · 12.6 KB
/
confex.ex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
defmodule Confex do
@moduledoc """
Confex simplifies reading configuration at run-time with adapter-based system for resolvers.
# Configuration tuples
Whenever there is a configuration that should be resolved at run-time you need to replace its value in `config.exs`
by Confex configuration type. Common structure:
```elixir
@type fetch_statement :: {adapter :: atom() | module(), value_type :: value_type, key :: any(), default :: any()}
| {value_type :: value_type, key :: any()}
| {key :: any(), default :: any()}
| {key :: any()}
```
If `value_type` is set, Confex will automatically cast its value. Otherwise, default type of `:string` is used.
| Confex Type | Elixir Type | Description |
| ----------- | ----------------- | ----------- |
| `:string` | `String.t` | Default. |
| `:integer` | `Integer.t` | Parse Integer value in string. |
| `:float` | `Float.t` | Parse Float value in string. |
| `:boolean` | `true` or `false` | Cast 'true', '1', 'yes' to `true`; 'false', '0', 'no' to `false`. |
| `:atom` | `atom()` | Cast string to atom. |
| `:module` | `module()` | Cast string to module name. |
| `:list` | `List.t` | Cast comma-separated string (`1,2,3`) to list (`[1, 2, 3]`). |
| `:charlist` | `charlist()` | Cast string to charlist. |
# Custom type casting
You can use your own casting function by replacing type with `{module, function, arguments}` tuple,
Confex will call that function with `apply(module, function, [value] ++ arguments)`.
This function returns either `{:ok, value}` or `{:error, reason :: String.t}` tuple.
# Adapters
* `:system` - read configuration from system environment;
* `:system_file` - read file path from system environment and read configuration from this file.
You can create adapter by implementing `Confex.Adapter` behaviour with your own logic.
# Examples
* `var` - any bare values will be left as-is;
* `{:system, "ENV_NAME", default}` - read string from "ENV_NAME" environment variable or return `default` \
if it's not set or has empty value;
* `{:system, "ENV_NAME"}` - same as above, with default value `nil`;
* `{:system, :integer, "ENV_NAME", default}` - read string from "ENV_NAME" environment variable and cast it \
to integer or return `default` if it's not set or has empty value;
* `{:system, :integer, "ENV_NAME"}` - same as `{:system, :integer, "ENV_NAME", nil}`;
* `{{:via, MyAdapter}, :string, "ENV_NAME", default}` - read value by key "ENV_NAME" via adapter `MyAdapter` \
or return `default` if it's not set or has empty value;
* `{{:via, MyAdapter}, :string, "ENV_NAME"}` - same as above, with default value `nil`;
* `{:system, {MyApp.MyType, :cast, [:foo]}, "ENV_NAME"}` - `MyApp.MyType.cast(value, :foo)` call would be made \
to resolve environment variable value.
"""
alias Confex.Resolver
@typep app :: Application.app()
@typep key :: Application.key()
@typep value :: Application.value()
@type configuration_tuple ::
{value_type :: Confex.Type.t(), key :: any(), default :: any()}
| {value_type :: Confex.Type.t(), key :: any()}
| {key :: any(), default :: any()}
| {key :: any()}
@doc """
Returns the value for key in app’s environment in a tuple.
This function mimics `Application.fetch_env/2` function.
If the configuration parameter does not exist or can not be parsed, the function returns :error.
## Example
iex> :ok = System.put_env("MY_TEST_ENV", "foo")
...> Application.put_env(:myapp, :test_var, {:system, "MY_TEST_ENV"})
...> {:ok, "foo"} = #{__MODULE__}.fetch_env(:myapp, :test_var)
{:ok, "foo"}
iex> :ok = System.delete_env("MY_TEST_ENV")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV", "bar"})
...> {:ok, "bar"} = #{__MODULE__}.fetch_env(:myapp, :test_var)
{:ok, "bar"}
iex> :ok = System.delete_env("MY_TEST_ENV")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV"})
...> :error = #{__MODULE__}.fetch_env(:myapp, :test_var)
:error
iex> :ok = System.put_env("MY_TEST_ENV", "foo")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV"})
...> :error = #{__MODULE__}.fetch_env(:myapp, :test_var)
:error
iex> Application.put_env(:myapp, :test_var, 1)
...> {:ok, 1} = #{__MODULE__}.fetch_env(:myapp, :test_var)
{:ok, 1}
"""
@spec fetch_env(app :: app(), key :: key()) :: {:ok, value()} | :error
def fetch_env(app, key) do
with {:ok, config} <- Application.fetch_env(app, key),
{:ok, config} <- Resolver.resolve(config) do
{:ok, config}
else
:error -> :error
{:error, _reason} -> :error
end
end
@doc """
Returns the value for key in app’s environment.
This function mimics `Application.fetch_env!/2` function.
If the configuration parameter does not exist or can not be parsed, raises `ArgumentError`.
## Example
iex> :ok = System.put_env("MY_TEST_ENV", "foo")
...> Application.put_env(:myapp, :test_var, {:system, "MY_TEST_ENV"})
...> "foo" = #{__MODULE__}.fetch_env!(:myapp, :test_var)
"foo"
iex> :ok = System.delete_env("MY_TEST_ENV")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV", "bar"})
...> "bar" = #{__MODULE__}.fetch_env!(:myapp, :test_var)
"bar"
iex> :ok = System.delete_env("MY_TEST_ENV")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV"})
...> #{__MODULE__}.fetch_env!(:myapp, :test_var)
** (ArgumentError) can't fetch value for key `:test_var` of application `:myapp`, can not resolve key MY_TEST_ENV value via adapter Elixir.Confex.Adapters.SystemEnvironment
iex> :ok = System.put_env("MY_TEST_ENV", "foo")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV"})
...> #{__MODULE__}.fetch_env!(:myapp, :test_var)
** (ArgumentError) can't fetch value for key `:test_var` of application `:myapp`, can not cast "foo" to Integer
iex> Application.put_env(:myapp, :test_var, 1)
...> 1 = #{__MODULE__}.fetch_env!(:myapp, :test_var)
1
"""
@spec fetch_env!(app :: app(), key :: key()) :: value() | no_return
def fetch_env!(app, key) do
config = Application.fetch_env!(app, key)
case Resolver.resolve(config) do
{:ok, config} ->
config
{:error, {_reason, message}} ->
raise ArgumentError, "can't fetch value for key `#{inspect(key)}` of application `#{inspect(app)}`, #{message}"
end
end
@doc """
Returns the value for key in app’s environment.
This function mimics `Application.get_env/2` function.
If the configuration parameter does not exist or can not be parsed, returns default value or `nil`.
## Example
iex> :ok = System.put_env("MY_TEST_ENV", "foo")
...> Application.put_env(:myapp, :test_var, {:system, "MY_TEST_ENV"})
...> "foo" = #{__MODULE__}.get_env(:myapp, :test_var)
"foo"
iex> :ok = System.delete_env("MY_TEST_ENV")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV", "bar"})
...> "bar" = #{__MODULE__}.get_env(:myapp, :test_var)
"bar"
iex> :ok = System.delete_env("MY_TEST_ENV")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV"})
...> nil = #{__MODULE__}.get_env(:myapp, :test_var)
nil
iex> :ok = System.delete_env("MY_TEST_ENV")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV"})
...> "baz" = #{__MODULE__}.get_env(:myapp, :test_var, "baz")
"baz"
iex> :ok = System.put_env("MY_TEST_ENV", "foo")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV"})
...> nil = #{__MODULE__}.get_env(:myapp, :test_var)
nil
iex> nil = #{__MODULE__}.get_env(:myapp, :does_not_exist)
nil
iex> Application.put_env(:myapp, :test_var, 1)
...> 1 = #{__MODULE__}.get_env(:myapp, :test_var)
1
"""
@spec get_env(app :: app(), key :: key(), default :: value()) :: value()
def get_env(app, key, default \\ nil) do
with {:ok, config} <- Application.fetch_env(app, key),
{:ok, config} <- Resolver.resolve(config) do
config
else
:error -> default
{:error, _reason} -> default
end
end
@doc """
Reads all key-value pairs from an application environment and replaces them
with resolved values.
# Example
iex> :ok = System.put_env("MY_TEST_ENV", "foo")
...> Application.put_env(:myapp, :test_var, {:system, "MY_TEST_ENV"})
...> Confex.resolve_env!(:myapp)
...> "foo" = Application.get_env(:myapp, :test_var)
"foo"
iex> :ok = System.put_env("MY_TEST_ENV", "foo")
...> Application.put_env(:myapp, :test_var, {:system, :integer, "MY_TEST_ENV"})
...> Confex.resolve_env!(:myapp)
** (ArgumentError) can't fetch value for key `:test_var` of application `:myapp`, can not cast "foo" to Integer
The optional `opts` argument is passed through to the internal call to
`Application.put_env/4` and may be used to set the `timeout` and/or
`persistent` parameters.
*Warning!* Do not use this function if you want to change your environment
while VM is running. All `{:system, _}` tuples would be replaced with actual values.
"""
@spec resolve_env!(app :: app(), opts :: Keyword.t()) :: [{key(), value()}] | no_return
def resolve_env!(app, opts \\ []) do
app
|> Application.get_all_env()
|> Enum.map(&resolve_and_update_env(app, &1, opts))
end
defp resolve_and_update_env(app, {key, config}, opts) do
case Resolver.resolve(config) do
{:ok, config} ->
:ok = Application.put_env(app, key, config, opts)
{key, config}
{:error, {_reason, message}} ->
raise ArgumentError, "can't fetch value for key `#{inspect(key)}` of application `#{inspect(app)}`, " <> message
end
end
@doc """
Recursively merges configuration with default values.
Both values must be either in `Keyword` or `Map` structures, otherwise ArgumentError is raised.
## Example
iex> [b: 3, a: 1] = #{__MODULE__}.merge_configs!([a: 1], [a: 2, b: 3])
[b: 3, a: 1]
iex> %{a: 1, b: 3} = #{__MODULE__}.merge_configs!(%{a: 1}, %{a: 2, b: 3})
%{a: 1, b: 3}
iex> #{__MODULE__}.merge_configs!(%{a: 1}, [b: 2])
** (ArgumentError) can not merge default values [b: 2] with configuration %{a: 1} because their types mismatch, \
expected both to be either Map or Keyword structures
"""
@spec merge_configs!(config :: Keyword.t() | map, defaults :: Keyword.t() | map) :: Keyword.t() | map
def merge_configs!(config, []), do: config
def merge_configs!(nil, defaults), do: defaults
def merge_configs!(config, defaults) do
cond do
Keyword.keyword?(config) and Keyword.keyword?(defaults) ->
defaults
|> Keyword.merge(config, &compare/3)
|> Resolver.resolve!()
is_map(config) and is_map(defaults) ->
defaults
|> Map.merge(config, &compare/3)
|> Resolver.resolve!()
true ->
raise ArgumentError,
"can not merge default values #{inspect(defaults)} " <>
"with configuration #{inspect(config)} because their types mismatch, " <>
"expected both to be either Map or Keyword structures"
end
end
defp compare(_k, v1, v2) do
if is_map(v2) or Keyword.keyword?(v2) do
merge_configs!(v1, v2)
else
v2
end
end
# Helper to include configuration into module and validate it at compile-time/run-time.
@doc false
defmacro __using__(opts) do
quote bind_quoted: [opts: opts], location: :keep do
@otp_app Keyword.fetch!(opts, :otp_app)
@module_config_defaults Keyword.delete(opts, :otp_app)
@doc """
Returns module configuration.
If application environment contains values in `Keyword` or `Map` struct,
defaults from macro usage will be recursively merged with application configuration.
If one of the configuration parameters does not exist or can not be resolved, raises `ArgumentError`.
"""
@spec config() :: any()
def config do
@otp_app
|> Confex.get_env(__MODULE__)
|> Confex.merge_configs!(@module_config_defaults)
|> Confex.Resolver.resolve!()
|> validate_config!()
end
@spec validate_config!(config :: any()) :: any()
def validate_config!(config), do: config
defoverridable validate_config!: 1
end
end
end