-
Notifications
You must be signed in to change notification settings - Fork 0
/
a_star.asl
34 lines (29 loc) · 1.18 KB
/
a_star.asl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
/**
* A* implementation - From Jason project website
*/
{ register_function("search.h",2,"h") }
a_star( InitialState, Goal, Solution, Cost) :-
.set.add_all(Closed,[InitialState]) &
.queue.create(Open,priority) &
.queue.add(Open,s(0,0,[op(initial,InitialState)])) &
a_star_l( Open, Goal, s(_,Cost,SolutionR), Closed) &
.reverse(SolutionR,Solution).
a_star_l( Open, GoalState, s(F,G,[op(Op,GoalState)|Path]), Closed) :-
.queue.head(Open,s(F,G,[op(Op,GoalState)|Path])).
a_star_l( Open, GoalState, Solution, Closed) :-
.queue.remove(Open,s(F,G,[op(Op,State)|Path])) &
//.print("exploring ",State," to be explored ", .length(Open)) &
State \== GoalState &
.set.add(Closed, State) & // do not explore State again
.findall(
s(NF,NG,[ op(NOp,NewState), op(Op,State)|Path]), // new paths
( suc(State,NewState,Cost,NOp) &
not .member(NewState, Closed) &
NG = G + Cost & // cost to achieve NewState
NF = search.h(NewState,GoalState) + NG // cost + heuristic for new state
),
Suc
) &
//.print(" ",Suc) &
.queue.add_all(Open, Suc) &
a_star_l( Open, GoalState, Solution, Closed).