build.gradle

plugins {
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.6-SNAPSHOT" apply false
    id "com.matthewprenger.cursegradle" version "1.4.0"
    id "com.modrinth.minotaur" version "2.8.4"
}

architectury {
    minecraft = rootProject.minecraft_version
}


subprojects {
    apply plugin: "dev.architectury.loom"
//    apply plugin: "io.github.juuxel.loom-quiltflower"
    apply plugin: "com.matthewprenger.cursegradle"
    apply plugin: "com.modrinth.minotaur"


    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        mappings loom.layered() {
            it.officialMojangMappings {
                setNameSyntheticMembers(false)
            }
            it.parchment("org.parchmentmc.data:parchment-${rootProject.parchment_version}")
        }
    }

    var env = System.getenv()
    var modLoader = name

    var changelogFile = rootProject.file("changelog.md")
    var changelogText = changelogFile.exists() ? changelogFile.text : ""

    if (env.MODRINTH_TOKEN) {
        modrinth {
            projectId = mod_id
            uploadFile = tasks.remapJar
            additionalFiles.add(tasks.remapSourcesJar)
            gameVersions = [minecraft_version]
            if(modLoader == "forge"){
                loaders = [modLoader, "neoforge"]
            }else{
                loaders = [modLoader]
            }
            changelog = changelogText
            versionNumber = modLoader +"_"+ mod_version
            versionType = "release"

            if (modLoader == "fabric") {
                dependencies {
                    required.project "fabric-api"
                }
            } else {
            }
        }
    }

    if (env.CURSEFORGE_TOKEN) {
        curseforge {
            apiKey = env.CURSEFORGE_TOKEN
            project {
                id = rootProject.project_id
                changelog = changelogText
                changelogType = 'markdown'
                releaseType = 'release'
                addGameVersion rootProject.minecraft_version
                addGameVersion modLoader.capitalize()
                if(modLoader == "forge"){
                    addGameVersion "NeoForge"
                }
                mainArtifact(tasks.remapJar)
                addArtifact(tasks.remapSourcesJar)

                if (modLoader == "fabric") {
                    relations {
                        requiredDependency "fabric-api"
                    }
                } else {
                }
            }
        }
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    archivesBaseName = rootProject.mod_id
    version = rootProject.mod_version
    group = rootProject.maven_group

    repositories {

        flatDir {
            dirs 'mods'
        }

        mavenLocal()

        maven { url "https://maven.parchmentmc.org" }

        maven {
            url = "https://www.cursemaven.com"
            allowInsecureProtocol = true
        }
        maven {
            name = 'Ladysnake Mods'
            url = 'https://maven.ladysnake.org/releases'
        }

        maven { url 'https://jitpack.io' }

    }

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
        options.release = 17
    }

    java {
        withSourcesJar()

    }
}