feat: regen align-environments branch

an attempt to recreate and fix #794

modifications had to be made due to changes to configs etc
due to work on Zeus

this also notably excludes deploy scripts for the EIGEN token and TimelockControllers
specifically for Holesky, where they were already used

script/NoDelayTimelock.sol

@@ -0,0 +1,115 @@
+// SPDX-License-Identifier: BSD-3-Clause
+pragma solidity ^0.8.12;
+
+/// @notice Modified version of our mainnet timelock for use on Holesky
+/// Specifically, this removes SafeMath and changes `MINIMUM_DELAY` to `0 days`
+///
+/// See original version here: https://github.com/compound-finance/compound-protocol/blob/a3214f67b73310d547e00fc578e8355911c9d376/contracts/Timelock.sol
+contract NoDelayTimelock {
+
+    event NewAdmin(address indexed newAdmin);
+    event NewPendingAdmin(address indexed newPendingAdmin);
+    event NewDelay(uint indexed newDelay);
+    event CancelTransaction(bytes32 indexed txHash, address indexed target, uint value, string signature,  bytes data, uint eta);
+    event ExecuteTransaction(bytes32 indexed txHash, address indexed target, uint value, string signature,  bytes data, uint eta);
+    event QueueTransaction(bytes32 indexed txHash, address indexed target, uint value, string signature, bytes data, uint eta);
+
+    uint public constant GRACE_PERIOD = 14 days;
+    uint public constant MINIMUM_DELAY = 0;
+    uint public constant MAXIMUM_DELAY = 30 days;
+
+    address public admin;
+    address public pendingAdmin;
+    uint public delay;
+
+    mapping (bytes32 => bool) public queuedTransactions;
+
+
+    constructor(address admin_, uint delay_) {
+        require(delay_ >= MINIMUM_DELAY, "Timelock::constructor: Delay must exceed minimum delay.");
+        require(delay_ <= MAXIMUM_DELAY, "Timelock::setDelay: Delay must not exceed maximum delay.");
+
+        admin = admin_;
+        delay = delay_;
+    }
+
+    fallback() external payable { }
+
+    receive() external payable { }
+
+    function setDelay(uint delay_) public {
+        require(msg.sender == address(this), "Timelock::setDelay: Call must come from Timelock.");
+        require(delay_ >= MINIMUM_DELAY, "Timelock::setDelay: Delay must exceed minimum delay.");
+        require(delay_ <= MAXIMUM_DELAY, "Timelock::setDelay: Delay must not exceed maximum delay.");
+        delay = delay_;
+
+        emit NewDelay(delay);
+    }
+
+    function acceptAdmin() public {
+        require(msg.sender == pendingAdmin, "Timelock::acceptAdmin: Call must come from pendingAdmin.");
+        admin = msg.sender;
+        pendingAdmin = address(0);
+
+        emit NewAdmin(admin);
+    }
+
+    function setPendingAdmin(address pendingAdmin_) public {
+        require(msg.sender == address(this), "Timelock::setPendingAdmin: Call must come from Timelock.");
+        pendingAdmin = pendingAdmin_;
+
+        emit NewPendingAdmin(pendingAdmin);
+    }
+
+    function queueTransaction(address target, uint value, string memory signature, bytes memory data, uint eta) public returns (bytes32) {
+        require(msg.sender == admin, "Timelock::queueTransaction: Call must come from admin.");
+        require(eta >= getBlockTimestamp() + delay, "Timelock::queueTransaction: Estimated execution block must satisfy delay.");
+
+        bytes32 txHash = keccak256(abi.encode(target, value, signature, data, eta));
+        queuedTransactions[txHash] = true;
+
+        emit QueueTransaction(txHash, target, value, signature, data, eta);
+        return txHash;
+    }
+
+    function cancelTransaction(address target, uint value, string memory signature, bytes memory data, uint eta) public {
+        require(msg.sender == admin, "Timelock::cancelTransaction: Call must come from admin.");
+
+        bytes32 txHash = keccak256(abi.encode(target, value, signature, data, eta));
+        queuedTransactions[txHash] = false;
+
+        emit CancelTransaction(txHash, target, value, signature, data, eta);
+    }
+
+    function executeTransaction(address target, uint value, string memory signature, bytes memory data, uint eta) public payable returns (bytes memory) {
+        require(msg.sender == admin, "Timelock::executeTransaction: Call must come from admin.");
+
+        bytes32 txHash = keccak256(abi.encode(target, value, signature, data, eta));
+        require(queuedTransactions[txHash], "Timelock::executeTransaction: Transaction hasn't been queued.");
+        require(getBlockTimestamp() >= eta, "Timelock::executeTransaction: Transaction hasn't surpassed time lock.");
+        require(getBlockTimestamp() <= eta + GRACE_PERIOD, "Timelock::executeTransaction: Transaction is stale.");
+
+        queuedTransactions[txHash] = false;
+
+        bytes memory callData;
+
+        if (bytes(signature).length == 0) {
+            callData = data;
+        } else {
+            callData = abi.encodePacked(bytes4(keccak256(bytes(signature))), data);
+        }
+
+        // solium-disable-next-line security/no-call-value
+        (bool success, bytes memory returnData) = target.call{value: value}(callData);
+        require(success, "Timelock::executeTransaction: Transaction execution reverted.");
+
+        emit ExecuteTransaction(txHash, target, value, signature, data, eta);
+
+        return returnData;
+    }
+
+    function getBlockTimestamp() internal view returns (uint) {
+        // solium-disable-next-line security/no-block-members
+        return block.timestamp;
+    }
+}

script/configs/mainnet.json

@@ -26,7 +26,8 @@
             "pauserMultisig": "0x5050389572f2d220ad927CcbeA0D406831012390",
             "pauserRegistry": "0x0c431C66F4dE941d089625E5B423D00707977060",
             "proxyAdmin": "0x8b9566AdA63B64d1E1dcF1418b43fd1433b72444",
-            "timelock": "0xA6Db1A8C5a981d1536266D2a393c5F8dDb210EAF"
+            "timelock": "0xA6Db1A8C5a981d1536266D2a393c5F8dDb210EAF",
+            "foundationMultisig": "0xbb00DDa2832850a43840A3A86515E3Fe226865F2"
         },
         "core": {
             "avsDirectory": {
@@ -41,7 +42,7 @@
             },
             "rewardsCoordinator": {
                 "proxy": "0x7750d328b314EfFa365A0402CcfD489B80B0adda",
-                "impl": "0x5bf7c13D5FAdba224ECB3D5C0a67A231D1628785",
+                "impl": "0xb6738A8E7793D44c5895B6A6F2a62F6bF86Ba8d2",
                 "pendingImpl": "0x0000000000000000000000000000000000000000"
             },
             "slasher": {
@@ -106,19 +107,22 @@
                 "proxy": "0x83E9115d334D248Ce39a6f36144aEaB5b3456e75",
                 "impl": "0xB91c69Af3eE022bd0a59Da082945914BFDcEFFE3",
                 "pendingImpl": "0x0000000000000000000000000000000000000000",
-                "proxyAdmin": "0x3f5Ab2D4418d38568705bFd6672630fCC3435CC9"
+                "proxyAdmin": "0x3f5Ab2D4418d38568705bFd6672630fCC3435CC9",
+                "timelockController": "0xd6EC41E453C5E7dA5494f4d51A053Ab571712E6f"
             },
             "EIGEN": {
                 "proxy": "0xec53bf9167f50cdeb3ae105f56099aaab9061f83",
                 "impl": "0x7ec354c84680112d3cff1544ec1eb19ca583700b",
                 "pendingImpl": "0x0000000000000000000000000000000000000000",
-                "proxyAdmin": "0xB8915E195121f2B5D989Ec5727fd47a5259F1CEC"
+                "proxyAdmin": "0xB8915E195121f2B5D989Ec5727fd47a5259F1CEC",
+                "timelockController": "0x2520C6b2C1FBE1813AB5c7c1018CDa39529e9FF2"
             },
             "eigenStrategy": {
                 "proxy": "0xaCB55C530Acdb2849e6d4f36992Cd8c9D50ED8F7",
                 "impl": "0x27e7a3a81741b9fcc5ad7edcbf9f8a72a5c00428",
                 "pendingImpl": "0x0000000000000000000000000000000000000000"
             }
-        }
+        },
+        "emptyContract": "0x1f96861fEFa1065a5A96F20Deb6D8DC3ff48F7f9"
     }
 }