build.gradle

plugins {
    id 'java-library'
    id 'eclipse'
    id 'idea'
    id 'maven-publish'
    id 'net.neoforged.moddev' version '1.0.14'
}

tasks.named('wrapper', Wrapper).configure {
    distributionType = Wrapper.DistributionType.BIN
}

version = mod_version
group = mod_group_id

repositories {
    mavenLocal()
	maven { url "https://maven.jaackson.me" }
	maven { url "https://www.cursemaven.com" }
	maven { url "https://dvs1.progwml6.com/files/maven/" }
	maven { url "https://modmaven.k-4u.nl" }
	maven { url "https://maven.tterrag.com/" }
	maven { url 'https://www.jitpack.io' }
	flatDir { dirs '../FarmersDelight/build/libs' }
}


base {
    archivesName = mod_id
}

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

neoForge {
    version = project.neo_version

    parchment {
        mappingsVersion = project.parchment_mappings_version
        minecraftVersion = project.parchment_minecraft_version
    }

    accessTransformers = project.files('src/main/resources/META-INF/accesstransformer.cfg')

    runs {
        client {
            client()
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        server {
            server()
            programArgument '--nogui'
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        gameTestServer {
            type = "gameTestServer"
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        data {
            data()
            programArguments.addAll '--mod', project.mod_id, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
        }

        configureEach {
            systemProperty 'forge.logging.markers', 'REGISTRIES'
            logLevel = org.slf4j.event.Level.DEBUG
        }
    }

    mods {
        "${mod_id}" {
            sourceSet(sourceSets.main)
        }
    }
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

configurations {
    runtimeClasspath.extendsFrom localRuntime
}

dependencies {
	annotationProcessor 'org.spongepowered:mixin:0.8.5:processor'
	
	implementation "curse.maven:farmersdelight-398521:5878217"

	 // compile against the JEI API but do not include it at runtime
    compileOnly "mezz.jei:jei-1.21.1-common-api:${jei_version}"
    compileOnly "mezz.jei:jei-1.21.1-neoforge-api:${jei_version}"
    // at runtime, use the full JEI jar for Forge
    localRuntime "mezz.jei:jei-1.21.1-neoforge:${jei_version}"
	
	compileOnly "vazkii.patchouli:Patchouli:1.21-87-NEOFORGE:api"
    runtimeOnly "vazkii.patchouli:Patchouli:1.21-87-NEOFORGE"
}

// This block of code expands all declared replace properties in the specified resource targets.
// A missing property will result in an error. Properties are expanded using ${} Groovy notation.
// When "copyIdeResources" is enabled, this will also run before the game launches in IDE environments.
// See https://docs.gradle.org/current/dsl/org.gradle.language.jvm.tasks.ProcessResources.html
tasks.withType(ProcessResources).configureEach {
    var replaceProperties = [
            minecraft_version : minecraft_version, 
			minecraft_version_range: minecraft_version_range,
            neo_version : neo_version, 
			neo_version_range: neo_version_range,
            loader_version_range: loader_version_range,
            mod_id : mod_id, 
			mod_name: mod_name, 
			mod_license: mod_license, 
			mod_version: mod_version,
            mod_authors : mod_authors, 
			mod_description: mod_description,
    ]
    inputs.properties replaceProperties

    filesMatching(['META-INF/mods.toml']) {
        expand replaceProperties + [project: project]
    }
}

publishing {
    publications {
        register('mavenJava', MavenPublication) {
            from components.java
        }
    }
    repositories {
        maven {
            url "file://${project.projectDir}/repo"
        }
		
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}