build.gradle

plugins {
    id 'maven-publish'
    id 'java-library'
    alias libs.plugins.fabric.loom
    alias libs.plugins.minotaur
    alias libs.plugins.cursegradle
    alias libs.plugins.loom.quiltflower
}

archivesBaseName = project.archives_base_name
group = project.maven_group

boolean isBuild = System.getenv('GITHUB_WORKFLOW') == 'build'
version = !isBuild ? project.mod_version : "${project.mod_version}+build.${System.getenv('GITHUB_RUN_NUMBER')}"

allprojects {
    apply plugin: 'fabric-loom'
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17

    repositories {
        maven {
            name = 'Quilt'
            url = 'https://maven.quiltmc.org/repository/release'
        }
        maven {
            name = 'Quilt Snapshots'
            url = 'https://maven.quiltmc.org/repository/snapshot'
        }
        maven {
            name 'FabricMC'
            url 'https://maven.fabricmc.net'
        }
    }

    dependencies {
        //to change the versions see the libs.versions.toml file
        minecraft libs.minecraft
        mappings variantOf(libs.quilt.mappings) { classifier 'intermediary-v2' }
        modImplementation libs.fabric.loader

        modImplementation libs.fabric.api
    }

    processResources {
        inputs.property 'version', rootProject.version

        filesMatching('fabric.mod.json') {
            expand 'version': rootProject.version
        }
    }

    tasks.withType(JavaCompile).configureEach {
        // ensure that the encoding is set to UTF-8, no matter what the system default is
        // this fixes some edge cases with special characters not displaying correctly
        // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
        // If Javadoc is generated, this must be specified in that task too.
        it.options.encoding = 'UTF-8'

        it.options.release = 17
    }

    java {
        // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
        // if it is present.
        // If you remove this line, sources will not be generated.
        withSourcesJar()
    }

    jar {
        from('LICENSE') {
            rename { "${it}_${project.archivesBaseName}" }
        }
    }
    
    quiltflower {
        addToRuntimeClasspath.set(true)
    }
}

subprojects {
    apply plugin: 'fabric-loom'
    apply plugin: 'maven-publish'
    apply plugin: 'java-library'

    version = rootProject.version
}

repositories {
    maven {
        name 'JitPack'
        url 'https://jitpack.io'
    }
    maven {
        url 'https://maven.nucleoid.xyz/'
    }
}

rootProject.processResources.dependsOn(project(':api').processResources)

dependencies {
    // Add subprojects as dependency of root project
    implementation project(path: ':api', configuration: 'namedElements')
    include project(':api')

    // FabricPlaceholderApi
    modImplementation libs.placeholder.api
    include libs.placeholder.api
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    repositories {
        mavenLocal()
    }
}

modrinth {
    token = project.hasProperty('modrinth_token') ? project.property('modrinth_token') : System.getenv('MODRINTH_TOKEN')
    projectId = 'NLx6lJPJ'
    versionNumber = project.version
    versionName = "Player Events ${project.version} for Minecraft 1.20.1"
    uploadFile = remapJar
    changelog = "A changelog can be found at https://github.com/ByMartrixx/player-events/releases/tag/${version}"
    gameVersions = ['1.20.1']
    loaders = ['fabric', 'quilt']
    additionalFiles = [project(':api').remapJar]
}

curseforge {
    if (project.hasProperty('curse_api_key') || System.getenv('CURSE_API_KEY') != null) {
        apiKey = project.hasProperty('curse_api_key') ? project.property('curse_api_key') : System.getenv('CURSE_API_KEY')
    }
    project {
        id = '404348'
        changelog = "A changelog can be found at https://github.com/ByMartrixx/player-events/releases/tag/${version}"
        releaseType = 'release'
        addGameVersion '1.20.1'
        addGameVersion 'Fabric'
        addGameVersion 'Quilt'
        mainArtifact(remapJar) {
            displayName = "Player Events ${version} for Minecraft 1.20.1"
        }
        addArtifact(project(':api').remapJar) {
            displayName = "Player Events API ${version} for Minecraft 1.20.1"
        }
        afterEvaluate {
            uploadTask.dependsOn('remapJar')
            uploadTask.dependsOn('api:remapJar')
        }
    }
    options {
        forgeGradleIntegration = false
    }
}

publish.finalizedBy tasks.curseforge, tasks.modrinth, project(':api').tasks.publish