build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id "com.github.johnrengelman.shadow" version "8.1.1"
}

apply plugin: 'java'
apply plugin: 'maven-publish'
apply plugin: 'com.github.johnrengelman.shadow'

publishing {
    publications {
        //noinspection GroovyAssignabilityCheck
        shadow(MavenPublication) { publication ->
            project.shadow.component(publication)
        }
    }
}

repositories {
    maven { url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }
    maven { url = 'https://repo.codemc.io/repository/maven-releases/' } // PacketEvents
    maven { url = 'https://repo.codemc.io/repository/maven-snapshots/' } // PacketEvents
    mavenCentral()
}

dependencies {
    implementation(files("depends/packetevents-585.jar"))
    implementation(project(':api'))
    implementation 'com.github.cryptomorin:XSeries:11.2.2'
    implementation 'com.google.guava:guava:33.3.1-jre'
    implementation 'com.google.code.gson:gson:2.11.0'

    compileOnly 'org.spigotmc:spigot-api:1.21.3-R0.1-SNAPSHOT'

    compileOnly 'org.projectlombok:lombok:1.18.36'
    annotationProcessor 'org.projectlombok:lombok:1.18.36'

    testCompileOnly 'org.projectlombok:lombok:1.18.36'
    testAnnotationProcessor 'org.projectlombok:lombok:1.18.36'
}

group = 'de.feelix.sierra'
version = '1.5.2'
description = 'Sierra'

java.sourceCompatibility = JavaVersion.VERSION_1_8
java.targetCompatibility = JavaVersion.VERSION_1_8

shadowJar {
    minimize()
    relocate 'club.minnced', 'net.square.sierra.discord-webhooks'
    relocate 'com.google', 'net.square.sierra.google'
    relocate 'net.kyori', 'net.square.sierra.kyori'
    relocate 'kotlin', 'net.square.sierra.kotlin'
    relocate 'okhttp3', 'net.square.sierra.okhttp3'
    relocate 'com.cryptomorin', 'net.square.sierra.cryptomorin'
    relocate 'okio', 'net.square.sierra.okio'
    relocate 'javax.annotation', 'net.square.sierra.javax.annotation'
    relocate 'com.github.retrooper.packetevents', 'net.square.sierra.packetevents.api'
    relocate 'io.github.retrooper.packetevents', 'net.square.sierra.packetevents.api'
    relocate 'org.bstats', 'net.square.sierra.bstats'
    archiveFileName = "${project.name}-${project.version}.jar"
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}