settings.gradle

plugins {
    id "com.gradle.enterprise" version "3.16.2"
}

rootProject.name = 'consensusj'

if (JavaVersion.current().compareTo(JavaVersion.VERSION_17) < 0) {
    throw new RuntimeException("JDK 17 or later is required to compile ConsensusJ")
}

// JDK 8
    include 'cj-bitcoinj-dsl-gvy'               // Groovy DSL for bitcoinj

// JDK 9
    include 'cj-bitcoinj-util'                  // BlockUtil (and future stuff depending on only bitcoinj)

// JDK 11
    include 'consensusj-analytics'              // Reactive analytics libraries
    include 'consensusj-currency'               // JavaMoney Currency Provider(s)
    include 'consensusj-decentralized-id'       // W3C Decentralized ID library (in-process)
    include 'consensusj-exchange'               // JavaMoney Exchange Providers
    include 'consensusj-jsonrpc'                // JSON-RPC Java client
    include 'consensusj-jsonrpc-gvy'            // JSON-RPC Groovy client
    include 'consensusj-rx-jsonrpc'             // RxJava 3 adapter for JSON-RPC
    include 'consensusj-rx-zeromq'              // RxJava 3 adapter for ZeroMQ (uses JeroMQ)
    include 'cj-btc-rx'                         // bitcoinj-based RxJava interfaces
    include 'cj-btc-rx-peergroup'               // bitcoinj-based RxJava (Transaction) implementation
    include 'cj-btc-rx-jsonrpc'                 // RxJava 3 reactive Bitcoin JSON-RPC bitcoind client (uses ZeroMQ)
    include 'cj-btc-json'                       // JSON <-> Java Object mapping
    include 'cj-btc-jsonrpc'                    // Bitcoin JSON-RPC client using bitcoinj-based types
    include 'cj-btc-jsonrpc-gvy'                // Bitcoin JSON-RPC client with Groovy dynamic method support
    include 'cj-eth-jsonrpc'                    // Ethereum JSON-RPC client (experimental)
    include 'cj-nmc-jsonrpc'                    // Namecoin JSON-RPC client (experimental)

// JDK 17
    include 'consensusj-jsonrpc-daemon'         // JSON-RPC sample server
    include 'cj-bitcoinj-spock'                 // Spock tests/demos of basic bitcoinj capabilities
    include 'cj-bitcoinj-dsl-js'                // JavaScript DSL for bitcoinj via Nashorn
    include 'cj-btc-daemon'                     // Prototype Micronaut version of Bitcoin daemon
    include 'cj-btc-jsonrpc-integ-test'         // RPC-based integration tests of/using bitcoind
    include 'cj-btc-services'                   // bitcoinj-based service objects

if (JavaVersion.current().compareTo(JavaVersion.VERSION_21) >= 0) {
    System.err.println "Including JDK 21 modules because Java is ${JavaVersion.current()}"
    include 'consensusj-jsonrpc-cli'            // JSON-RPC CLI library and tool
    include 'cj-btc-cli'                        // Bitcoin JSON-RPC CLI
} else {
    System.err.println "Skipping JDK 21 modules, currently running Java ${JavaVersion.current()}"
}