gdb.config

target remote localhost:3333

define dumpmemory
  dump binary memory $arg0.dump 0x20000000 0x20020000
end

define dc
  dumpmemory $arg0
  continue
end

define b_file_open
  break *0x0809e16a
  commands
    silent
    printf "file_open(%h, %s, %s),", $r0, $r1, $r2
    #x/s $r1
    #x/s $r2
  end
end

define b_task
  # This breakpoint is called from two different places, only one(uncommented) of which calls the actual task subroutine
  # break *0x080d0cb2 
  break *0x080f0574
  condition $bpnum $r4 == $breakTaskNum
    commands
    printf "Task #%d\n", $r4
  end

  set $breakTaskNum = $arg0

  disable $bpnum
  enable $bpnum
end

define b_log_tasks
  break *0x080f0574
  commands
    silent
    printf "  Task #%d (%x)\n", $r4, $pc
    continue
  end
end

define b_fvar
  watch *(0x2000e948 + 4 * $arg0)
  commands
    silent
    printf "  fvars[%x] write", $arg0
  end
end

define b_fvar_read
  rwatch *(0x2000e948 + 4 * $arg0)
  commands
    silent
    printf "  fvars[%x] read", $arg0
  end
end


# break *0x080bc992
# commands
# silent
# printf "Target=%.2f, %.2f\n",*(0x2000e948 + 4*0x2a), *(0x2000e948 + 4*0x2d)
# continue 10
# end

# display/f *0x2000e9ec
# watch *0x2000e9ec